library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
entity Lab3_Adder1 is
Port ( cin : in STD_LOGIC;
a : in STD_LOGIC_VECTOR (3 downto 0);
b : in STD_LOGIC_VECTOR (3 downto 0);
s : out STD_LOGIC_VECTOR (3 downto 0);
cout : out STD_LOGIC);
end Lab3_Adder1;
architecture Behavioral of Lab3_Adder1 is
SIGNAL c : STD_LOGIC_VECTOR (4 DOWNTO 0);
begin
c(0) <= cin;
s <= a XOR b XOR c (3 DOWNTO 0);
c (4 DOWNTO 1) <= (a AND b) OR (a AND c(3 DOWNTO 0)) OR (b AND c(3 DOWNTO 0));
cout <= c(4);
end Behavioral;
你好，我是第一次使用这个论坛。我正在 VHDL 上进行华莱士树乘法。上面的代码是全加器的代码。我想知道我们如何在主代码中调用函数/组件？ （就像 C 编程一样）。我想在我的主代码中调用这个全加器。
（如果有任何错误，我的英语很抱歉，我是法国人）
在 VHDL 中调用函数就像在 C 中一样 - 可以初始化常量、信号或变量，也可以作为进程中的顺序语句。但现在这并不重要。
但你不调用组件！这就像在 C++ 中调用对象一样 - 完全没有意义！
在 VHDL 中，您可以实例化组件或（更简单！）实体，并使用信号来互连它们的端口。这（非常非常粗略地）更像是用面向对象的语言声明对象和发送消息。这称为“结构 VHDL”，通常出现在 VHDL 设计的顶层，用于创建和互连 CPU、内存接口、FFT 处理器等组件。
鉴于您的实体
entity Lab3_Adder1 is
Port ( cin : in STD_LOGIC;
a : in STD_LOGIC_VECTOR (3 downto 0);
b : in STD_LOGIC_VECTOR (3 downto 0);
s : out STD_LOGIC_VECTOR (3 downto 0);
cout : out STD_LOGIC);
end Lab3_Adder1;
例如，我可以构建一个 8 位加法器，如下所示：
entity Adder_8bit is
Port ( cin : in STD_LOGIC;
a : in STD_LOGIC_VECTOR (7 downto 0);
b : in STD_LOGIC_VECTOR (7 downto 0);
s : out STD_LOGIC_VECTOR (7 downto 0);
cout : out STD_LOGIC);
end Adder_8bit;
architecture Structural of Adder_8bit is
signal carry_int : std_logic; -- between lower and upper halves
begin
-- We need to create and connect up two adders
LSB_adder : entity work.Lab3_Adder1
Port Map(
cin => cin,
a => a(3 downto 0),
b => b(3 downto 0),
s => s(3 downto 0),
cout => carry_int
);
MSB_adder : entity work.Lab3_Adder1
Port Map(
cin => carry_int,
a => a(7 downto 4),
b => b(7 downto 4),
s => s(7 downto 4),
cout => cout
);
end Structural;
本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)
