Unity之使UI显示在最上层

一、原理

• Camera Depth：摄像机深度。深度值越小(越浅)，越浮于表面，越近(前)。
• Sorting Layer：排序层级。
• Order In Layer：在排序层中的层级。
• Render Queue：在Shader中对Tags的Queue进行设置。
• ZDepth：Z轴，物体与摄像机的距离。

RenderQueue 2500以下，由近到远排序优先（不透明）
RenderQueue 2500以上， 由远到近排序优先（透明）

RenderQueue在2500的同侧：
Camera Depth > Sorting Layer > Order In Layer > RenderQueue > ZDepth
RenderQueue在2500的不同侧：
Camera Depth > RenderQueue > Sorting Layer > Order In Layer > ZDepth

二、不同大小的RenderQueue，让UI显示在模型上面

给UI绑定此Shader的材质球，设置RenderQueue=3000。
一般不透明模型材质球的RenderQueue=2000，属于2500不同侧情况，在其他条件相同时，RenderQueue小的先渲染(排队的位置靠前，队列先进先出，可以这么理解)，所以UI(3000)比模型(2000)大，后渲染，UI显示在模型上面。

Shader "UI/Overlay"
{
	Properties
	{
		[PerRendererData] _MainTex ("Font Texture", 2D) = "white" {}
		_Color("Tint", Color) = (1,1,1,1)
		_StencilComp ("Stencil Comparison", Float) = 8
		_Stencil ("Stencil ID", Float) = 0
		_StencilOp ("Stencil Operation", Float) = 0
		_StencilWriteMask ("Stencil Write Mask", Float) = 255
		_StencilReadMask ("Stencil Read Mask", Float) = 255
		_ColorMask ("Color Mask", Float) = 15
	}
	
	SubShader
	{
		LOD 100

		Tags
		{
			"Queue" = "Transparent"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent"
			"PreviewType"="Plane"
			"CanUseSpriteAtlas" = "True"
		}

		Stencil
		{
			Ref [_Stencil]
			Comp [_StencilComp]
			Pass [_StencilOp] 
			ReadMask [_StencilReadMask]
			WriteMask [_StencilWriteMask]
		}
		
		Cull Off
		Lighting Off
		ZWrite Off
		ZTest Always
		Offset -1, -1
		Blend SrcAlpha OneMinusSrcAlpha
		ColorMask [_ColorMask]

		Pass
		{
			CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				#include "UnityCG.cginc"
				#include "UnityUI.cginc"

				struct appdata_t
				{
					float4 vertex : POSITION;
					float2 texcoord : TEXCOORD0;
					float4 color : COLOR;
				};
	
				struct v2f
				{
					float4 vertex : SV_POSITION;
					half2 texcoord : TEXCOORD0;
					fixed4 color : COLOR;
				};
	
				sampler2D _MainTex;
				float4 _MainTex_ST;
				fixed4 _Color;
				fixed4 _TextureSampleAdd;
				
				v2f vert (appdata_t v)
				{
					v2f o;
					o.vertex = UnityObjectToClipPos(v.vertex);
					o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
					o.color = v.color * _Color;
#ifdef UNITY_HALF_TEXEL_OFFSET
					o.vertex.xy += (_ScreenParams.zw-1.0)*float2(-1,1);
#endif
					return o;
				}
				
				fixed4 frag (v2f i) : SV_Target
				{
					fixed4 col = (tex2D(_MainTex, i.texcoord) + _TextureSampleAdd) * i.color;
					 clip (col.a - 0.01);
					return col;
				}
			ENDCG
		}
	}
}

三、不同大小的Sorting Layer，让UI显示在粒子特效上面

Canvas的RenderMode != Screen Space - Overlay时(空间画布，非屏幕画布)，UI设置了RenderQueue=3000，虽然可以显示在模型上层，但是粒子特效的RenderQueue也是3000，这个时候同队列，都是模型摄像机，可以通过更改Sorting Layer使UI显示在粒子特效上面。

SortingLayer小的，先渲染。后渲染的“盖”在先渲染的上面。
画布：Canvas->SortingLayer。
粒子：ParticleSystem->Renderer->SortingLayerID。