初学Unity ShaderLab的时候，一定有接触过Unity Shader中的Tags标签块，比如：
<span style="white-space:pre"> </span>"LightMode"="Vertex"
"Queue"="Transparent"
"IgnoreProjector"="True"
"RenderType"="Transparent"
"PreviewType"="Plane"但是很多人对RenderType的了解可能相比其他标签要稍微淡薄一些，只知道比如渲染不透明物体使用Opaque，渲染透明物体使用Transparent等，而官网上有提到RenderType会用于材质替代渲染（RenderWithShader SetReplacementShader)，但究竟是如何去使用的，今天我总结下自己的理解。
首先，关于材质替代渲染，其主要就是Camera类的两个函数SetReplacementShader和RenderWithShader，其形参完全一样，第一个参数是用于替代的shader，以下记为RPShader，后一个参数是个字符串，表示用于替代的标签，包括自定义标签，以下记为mType，也就是假如我们调用SetReplacementShader(RPShader,"mType")，这个摄像机会检查所有渲染到的物体的shader，检查其是否包含mType标签，如果不存在则这个物体将不渲染，如果存在，在看这个标签的值，假如"mType"="A"，则在RPShader中找到"mType"="A"的subshader并用它来替代这个物体，假如RPShader中不包含"mType"="A"的标签，那么这个物体也不会渲染。
接下来，我们需要去unity的内置shader中找一个shader，（内置shader请去官网下载源码）。
我们找到内置shader源码路径下这个文件夹：\DefaultResources，在里面可以找到这个shader：Camera-DepthNormalTexture.shader，(PS:5.x之前的版本还能找到Camera-DepthTexture.shader，从内容上看，其似乎会在UNITY_MIGHT_NOT_HAVE_DEPTH_TEXTURE这个宏条件成立的情况下渲染深度，之前尝试使用这个shader做替代渲染但没有成功得到和_CameraDepthTexture一样的效果，后来官网上看到这句：
UNITY_MIGHT_NOT_HAVE_DEPTH_TEXTURE - defined if a platform might emulate shadow maps or depth textures by manually rendering depth into a texture.
所以5.x中我们已经找不到Camera-DepthTexture.shader这个shader了)
（补充：后来在5.x中研究了_CameraDepthTexture的渲染，写到这篇文章里了：http://blog.csdn.net/mobilebbki399/article/details/50559732）
打开Camera-DepthNormalTexture.shader，其内容如下：
Shader "Hidden/Camera-DepthNormalTexture" {
Properties {
_MainTex ("", 2D) = "white" {}
_Cutoff ("", Float) = 0.5
_Color ("", Color) = (1,1,1,1)
}
SubShader {
Tags { "RenderType"="Opaque" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct v2f {
float4 pos : SV_POSITION;
float4 nz : TEXCOORD0;
};
v2f vert( appdata_base v ) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
fixed4 frag(v2f i) : SV_Target {
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TransparentCutout" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
uniform float4 _MainTex_ST;
v2f vert( appdata_base v ) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
uniform fixed4 _Color;
fixed4 frag(v2f i) : SV_Target {
fixed4 texcol = tex2D( _MainTex, i.uv );
clip( texcol.a*_Color.a - _Cutoff );
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TreeBark" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "UnityBuiltin3xTreeLibrary.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
v2f vert( appdata_full v ) {
v2f o;
TreeVertBark(v);
o.pos = mul( UNITY_MATRIX_MVP, v.vertex );
o.uv = v.texcoord.xy;
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
fixed4 frag( v2f i ) : SV_Target {
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TreeLeaf" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "UnityBuiltin3xTreeLibrary.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
v2f vert( appdata_full v ) {
v2f o;
TreeVertLeaf(v);
o.pos = mul( UNITY_MATRIX_MVP, v.vertex );
o.uv = v.texcoord.xy;
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
fixed4 frag( v2f i ) : SV_Target {
half alpha = tex2D(_MainTex, i.uv).a;
clip (alpha - _Cutoff);
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TreeOpaque" "DisableBatching"="True" }
Pass {
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
float4 nz : TEXCOORD0;
};
struct appdata {
float4 vertex : POSITION;
float3 normal : NORMAL;
fixed4 color : COLOR;
};
v2f vert( appdata v ) {
v2f o;
TerrainAnimateTree(v.vertex, v.color.w);
o.pos = mul( UNITY_MATRIX_MVP, v.vertex );
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
fixed4 frag(v2f i) : SV_Target {
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TreeTransparentCutout" "DisableBatching"="True" }
Pass {
Cull Back
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
struct appdata {
float4 vertex : POSITION;
float3 normal : NORMAL;
fixed4 color : COLOR;
float4 texcoord : TEXCOORD0;
};
v2f vert( appdata v ) {
v2f o;
TerrainAnimateTree(v.vertex, v.color.w);
o.pos = mul( UNITY_MATRIX_MVP, v.vertex );
o.uv = v.texcoord.xy;
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
fixed4 frag(v2f i) : SV_Target {
half alpha = tex2D(_MainTex, i.uv).a;
clip (alpha - _Cutoff);
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
Pass {
Cull Front
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
struct appdata {
float4 vertex : POSITION;
float3 normal : NORMAL;
fixed4 color : COLOR;
float4 texcoord : TEXCOORD0;
};
v2f vert( appdata v ) {
v2f o;
TerrainAnimateTree(v.vertex, v.color.w);
o.pos = mul( UNITY_MATRIX_MVP, v.vertex );
o.uv = v.texcoord.xy;
o.nz.xyz = -COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
fixed4 frag(v2f i) : SV_Target {
fixed4 texcol = tex2D( _MainTex, i.uv );
clip( texcol.a - _Cutoff );
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="TreeBillboard" }
Pass {
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
v2f vert (appdata_tree_billboard v) {
v2f o;
TerrainBillboardTree(v.vertex, v.texcoord1.xy, v.texcoord.y);
o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
o.uv.x = v.texcoord.x;
o.uv.y = v.texcoord.y > 0;
o.nz.xyz = float3(0,0,1);
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
fixed4 frag(v2f i) : SV_Target {
fixed4 texcol = tex2D( _MainTex, i.uv );
clip( texcol.a - 0.001 );
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="GrassBillboard" }
Pass {
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
fixed4 color : COLOR;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
v2f vert (appdata_full v) {
v2f o;
WavingGrassBillboardVert (v);
o.color = v.color;
o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
o.uv = v.texcoord.xy;
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
fixed4 frag(v2f i) : SV_Target {
fixed4 texcol = tex2D( _MainTex, i.uv );
fixed alpha = texcol.a * i.color.a;
clip( alpha - _Cutoff );
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
SubShader {
Tags { "RenderType"="Grass" }
Pass {
Cull Off
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "TerrainEngine.cginc"
struct v2f {
float4 pos : SV_POSITION;
fixed4 color : COLOR;
float2 uv : TEXCOORD0;
float4 nz : TEXCOORD1;
};
v2f vert (appdata_full v) {
v2f o;
WavingGrassVert (v);
o.color = v.color;
o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
o.uv = v.texcoord;
o.nz.xyz = COMPUTE_VIEW_NORMAL;
o.nz.w = COMPUTE_DEPTH_01;
return o;
}
uniform sampler2D _MainTex;
uniform fixed _Cutoff;
fixed4 frag(v2f i) : SV_Target {
fixed4 texcol = tex2D( _MainTex, i.uv );
fixed alpha = texcol.a * i.color.a;
clip( alpha - _Cutoff );
return EncodeDepthNormal (i.nz.w, i.nz.xyz);
}
ENDCG
}
}
Fallback Off
}
（PS:顺便可以注意一下这个shader的完整路径名前面包括一个Hidden，当然你也可以这么给你的shader写上这个，这意味着你的shader在材质面板的shader选择界面中是隐藏的，unity很多内置的特殊功能的shader都使用了这个前缀路径，包括我们最熟悉的粉红色ErrorShader ^_^)
接下来讲解这个内置的Camera-DepthNormalTexture.shader，注意这个shader包含了很多SubShader，其中几乎包含了所有我们熟知的RenderType，不过没有Transparent，这个shader的主要作用就是当我们开启摄像机的DepthTextureMode为DepthNormals时该摄像机会使用这个shader以及"RenderType"这个标签做替代渲染，也就是SetReplacementShader(Camera-DepthNormalTexture,"RenderType")，刚刚有提过，只有被替代的shader中包含RenderType标签，且这个标签的值在替代的shader中存在，才会用这个SubShader去替代，显然RenderType=Transparent的标签在这个Camera-DepthNormalTexture.shader中并不存在。
当然_CameraDepthNormalsTexture我们知道其存储的内容是法线和深度，UnityCG.cginc文件中有定义两个函数，EncodeDepthNormal和DecodeDepthNormal用于对法线和深度进行编码和解码，我们已经看到在Camera-DepthNormalTexture.shader中的SubShader都是输出经过EncodeDepthNormal的深度和法线，其法线会被编码到xy分量，深度编码到zw分量。所以使用的时候需要通过DecodeDepthNormal将其解码。
以下是我尝试直接用这个shader做替代渲染的结果：
如下，一图是原始图像，二图是直接输出_CameraDepthNormalsTexture的结果，三图是我直接做替代渲染后得到的结果：
可以看到直接替代渲染和_CameraDepthNormalsTexture的内容是一样的，证明unity中_CameraDepthNormalsTexture是通过这个shader及RenderType标签做替代渲染得到的，其中RenderType=Transparent的物体并没有被写入_CameraDepthNormalsTexture，而RenderType=TransparentCutout的物体被裁切的地方也不会写入_CameraDepthNormalsTexture。
接下来尝试将两张图解码获取深度图：
以下一图是原始图像，二图是直接输出_CameraDepthTexture，三图是输出Linear01Depth(tex2D(_CameraDepthTexture,i.uv).r)，四图是输出经过Decode解码的_CameraDepthNormalsTexture的深度，五图是输出我直接替代渲染后并经过Decode解码的深度：
可以注意到三、四、五这三张图的颜色范围相近，也就是说_CameraDepthNormalsTexture中存的深度值是在eye到farClipPlane之间范围为0-1的，通过Linear01Depth函数将_CameraDepthTexture转换后输出的也是这个结果（图三）。
不过注意图三会发现第五个shader，其RenderType=Opaque的物体并没有被写入_CameraDepthTexture，虽然上图是在测试的时候关闭了它的zwrite，但实际上开启zwrite得到的也是这个效果，这是因为这个shader其内容只包含一个RenderType=Opaque的pass，是从Unlit shader的基础上修改的，之前有提到过_CameraDepthTexture在5.x中似乎不再是通过替代渲染得到了，而_CameraDepthNormalsTexture貌似还是替代渲染获得的，所以图四和图五这个shader显示都是正常的，同样是在无论zwrite是否开启的情况下。
最后一个，就是注意到我的最后一个物体的shader其RenderType=Opaque，但是zwrite off，也就是说不会写入深度缓存，但因为其RenderType=Opaque的，所以对于_CameraDepthNormalsTexture其还是未关闭写入的。
以上就是经过试验得出的结论，希望对你理解RenderType的作用有所帮助。
更多内容关注我的个人博客：http://www.lsngo.net
