Unity3D Sprite ...但是单面的？

团结优秀Sprites (Unity优秀的新精灵 http://docs.unity3d.com/ScriptReference/Sprite.html），除其他有价值的优点外，实际上是双面的。

在 2D 或 3D 用例中，您可以翻转这些小混蛋，但仍然从后面看到它们 - 它们是从两侧渲染的。

我也喜欢它们使用的无光照着色器（即 Sprite-Default，而不是 Sprite-Diffuse）。

但是，我需要一个老式的单面Sprite.

幸运的是，你可以免费下载Unity使用的优秀着色器的源码...令人困惑的是，你不能只在编辑器中打开它，而是看here http://forum.unity3d.com/threads/builtin-unity-shaders-source.2085/从那时起here https://unity3d.com/get-unity/download/archive.

After 涉及廉价威士忌的大量持续努力，我对着色器进行了两 (2) 次修改。

1. 我将文件第一行的名称更改为“DefaultSingle”而不是“Default”

2. 我评论掉了这条线Cull Off

（然后我做了一个新的Material，将其称为“Sprite Single Sided”，将着色器设置为这个新着色器，然后Sprite我用新材料替换了材料槽。）

事实上，我是否因进行此修改而搞砸了着色器中的任何内容？一个人可以愉快地注释掉“Cull off”而不引起进一步的问题吗？改变通常使用的材料是否有一些问题？Sprite（你无法“看到”它，所以我不知道）。更广泛地说，是否有更正确的方法来实现单面Sprite?

// file "Sprites-DefaultSingle.shader"
Shader "Sprites/DefaultSingle"
{
  Properties
  {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
  }

  SubShader
  {
    Tags
    { 
      "Queue"="Transparent" 
      "IgnoreProjector"="True" 
      "RenderType"="Transparent" 
      "PreviewType"="Plane"
      "CanUseSpriteAtlas"="True"
    }

  ///  Cull Off
    Lighting Off
    ZWrite Off
    Blend One OneMinusSrcAlpha

    Pass
    {
    CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma multi_compile _ PIXELSNAP_ON
      #pragma shader_feature ETC1_EXTERNAL_ALPHA
      #include "UnityCG.cginc"
      
      struct appdata_t
      {
        float4 vertex   : POSITION;
        float4 color    : COLOR;
        float2 texcoord : TEXCOORD0;
      };

      struct v2f
      {
        float4 vertex   : SV_POSITION;
        fixed4 color    : COLOR;
        float2 texcoord  : TEXCOORD0;
      };
      
      fixed4 _Color;

      v2f vert(appdata_t IN)
      {
        v2f OUT;
        OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
        OUT.texcoord = IN.texcoord;
        OUT.color = IN.color * _Color;
        #ifdef PIXELSNAP_ON
        OUT.vertex = UnityPixelSnap (OUT.vertex);
        #endif

        return OUT;
      }

      sampler2D _MainTex;
      sampler2D _AlphaTex;

      fixed4 SampleSpriteTexture (float2 uv)
      {
        fixed4 color = tex2D (_MainTex, uv);

#if ETC1_EXTERNAL_ALPHA
        // get the color from an external texture ..
        color.a = tex2D (_AlphaTex, uv).r;
#endif //ETC1_EXTERNAL_ALPHA

        return color;
      }

      fixed4 frag(v2f IN) : SV_Target
      {
        fixed4 c = SampleSpriteTexture (IN.texcoord) * IN.color;
        c.rgb *= c.a;
        return c;
      }
    ENDCG
    }
  }
}

这不会造成任何问题，并且是正确的做事方式。如果你想真正明确地表达它，你可以将该行更改为Cull Back而不是将其注释掉，而是将背面剔除定义为默认行为，因此只需将其删除就可以了。