了解 F# 尾递归

最近在学习F#。 我尝试以不同的方式解决问题。 像这样：

(*

[0;1;2;3;4;5;6;7;8] -> [(0,1,2);(3,4,5);(6,7,8)]

*)

//head-recursive
let rec toTriplet_v1 list=
    match list with
    | a::b::c::t -> (a,b,c)::(toTriplet_v1 t) 
    | _ -> []

//tail-recursive
let toTriplet_v2 list=
    let rec loop lst acc=
        match lst with
        | a::b::c::t -> loop t ((a,b,c)::acc)
        | _ -> acc
    loop list []

//tail-recursive(???)
let toTriplet_v3 list=
    let rec loop lst accfun=
        match lst with
        | a::b::c::t -> loop t (fun ls -> accfun ((a,b,c)::ls))
        | _ -> accfun []
    loop list (fun x -> x)

let funs = [toTriplet_v1; toTriplet_v2; toTriplet_v3];
funs |> List.map (fun x -> x [0..8]) |> List.iteri (fun i x -> printfn "V%d : %A" (i+1) x)

我想V2和V3的结果应该是一样的。 但是，我得到以下结果：

V1 : [(0, 1, 2); (3, 4, 5); (6, 7, 8)]
V2 : [(6, 7, 8); (3, 4, 5); (0, 1, 2)]
V3 : [(0, 1, 2); (3, 4, 5); (6, 7, 8)]

为什么V2和V3的结果不同？

V2采用标准累积变量完成尾递归：

loop ([0;1;2;3;4;5;6;7;8], []) ->
  loop ([3;4;5;6;7;8], [(0,1,2)]) ->
    loop ([6;7;8], [(3,4,5), (0,1,2)]) ->
      loop ([], [(6,7,8), (3,4,5), (0,1,2)]) ->
        [(6,7,8), (3,4,5), (0,1,2)]

V3 uses 延续 http://en.wikipedia.org/wiki/Continuation_passing_style，或者用简单的英语来说，累积功能:

loop ([0;1;2;3;4;5;6;7;8], x->x) ->
  loop ([3;4;5;6;7;8], x->(0;1;2)::x) ->
    loop ([6;7;8], x->(3;4;5)::x) ->
      loop ([], x->(6,7,8)::x) ->
        [(6,7,8)]  // x->(6,7,8)::x applies to []
    ->
      [(3,4,5);(6,7,8)] // x->(3,4,5)::x applies to [(6,7,8)]
  ->
    [(0,1,2);(3,4,5);(6,7,8)] // x->(0,1,2)::x applies to [(3,4,5);(6,7,8)]

您可以看到累加变量和累加函数之间的区别：

使用累积变量在最后一次调用时停止，因为累积变量存储答案。然而，累加函数仍然做了一些事情回溯最后一次通话后继续工作。应该注意的是，使用累积函数确实是尾递归，因为递归调用loop t (fun ls -> accfun ((a,b,c)::ls))实际上是last这个函数的声明。

顺便说一句，您提供的代码是展示尾递归函数概念的一个很好的例子。理解这些示例代码的一种方法是处理小案件正如我在上面两个插图中所做的那样。经过一些小案例的练习，你会对这个概念有更深入的理解。