Prolog 罗马数字（属性语法）

我正在做一项作业prolog /questions/tagged/prolog扫描数字列表并应返回该列表是否是有效的罗马数字以及数字的十进制值。前任）

1 ?- roman(N, ['I'], []).
N = 1
true.

2 ?- 

当我运行我认为应该工作的程序时，十进制值总是正确的，所以我猜我的合成属性部分是正确的，但对于应该返回 true 的数字列表，它总是返回 false。我还想补充一点，如果存在超过 3 个 Is、X 或 C，它就会在应该中止时中止。

1 ?- roman(N, ['I'], []).
N = 1 ;
false.

2 ?- roman(N, ['I','I','I','I'], []).
Error: too many I's
% Execution Aborted
3 ?- 

当我取出 N 并放入一个{write('N = '), write(N)}，它工作正常并返回true.

1 ?- roman(['I'], []).
N = 1
true.

当我删除时{N is ValH + ValT + ValU}它返回true但是，它不再显示十进制值。这是我的代码的第一行（因为这是当前的作业，我希望显示尽可能少的内容以获得答案）：

roman(N) --> hundreds(ValH), tens(ValT), units(ValU), {N is ValH + ValT + ValU}.

为什么使用 N 时返回 false，但不使用 N 则返回 true，我该如何修复它？

任务：以下BNF规范定义了罗马数字的语言 小于 1000：

<roman> ::= <hundreds> <tens> <units>
<hundreds> ::= <low hundreds> | CD | D <low hundreds> | CM
<low hundreds> ::= e | <low hundreds> C
<tens> ::= <low tens> | XL | L <low tens> | XC
<low tens> ::= e | <low tens> X
<units> ::= <low units> | IV | V <low units> | IX
<low units> ::= e | <low units> I

定义此语法的属性以执行两项任务：

a) 限制 X 的数量<low tens>，我在<low units>， 和 C 位于<low hundreds>不超过三个。

b) 提供一个属性<roman>给出了十进制值 罗马数字被定义。

定义这些任务所需的任何其他属性，但不要更改 BNF 语法。

您是否注意到语法是由重复 3 次的相同模式 (group//5) 组成，只是使用不同的符号？我喜欢紧凑的...

roman(N) -->
    group('C','D','M',100, H),
    group('X','L','C',10, T),
    group('I','V','X',1, U),
    {N is H+T+U}.
group(A,B,C, Scale, Value) -->
    (   g3(A, T)
    ;   [A, B], {T = 4}
    % thanks to Daniel and Will for catching bugs
    ;   [B], g3(A, F), {T is 5+F}
    ;   [B], {T is 5}
    ;   [A, C], {T = 9}
    ;   {T = 0}
    ),  {Value is Scale * T}.


g3(C, 1) --> [C].
g3(C, 2) --> [C,C].
g3(C, 3) --> [C,C,C].

一些测试

?- atom_chars('CMXXX',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'X', 'X'],
N = 930 ;
false.

?- atom_chars('CMXLVIII',L), phrase(roman(N),L).
L = ['C', 'M', 'X', 'L', 'V', 'I', 'I', 'I'],
N = 943 ;
false.

只是出于好奇，展示 DCG 的工作情况......

edit在丹尼尔和威尔评论之后……

?- atom_chars('VIII',L), phrase(roman(N),L).
L = ['V', 'I', 'I', 'I'],
N = 8 .

?- phrase(roman(X), ['L','I','X']).
X = 59 .