Common Lisp 案例和引用元素

我正在用 CL 编写一个地下城爬行游戏，但在处理案例表单时遇到了问题。

两件事情：

• Common Lisp 抱怨Duplicate keyform QUOTE in CASE statement
• (make-instance 'cl-rogue:tile tile-type 'wall)应打印为“#”，但无论我使用哪种图块类型，该对象都会打印为“”。

代码：

(in-package :cl-user)

(defpackage :cl-rogue
  (:use :common-lisp)
  (:export
    :*rows*
    :*cols*
    :*levels*
    :tile
    :tile-type
    :tile-contents
    :tile-hidden
    :tile-locked
    :tile-closed
    :main))

(in-package :cl-rogue)

(defparameter *cols* 80)
(defparameter *rows* 24)
(defparameter *levels* 26)

班上：

(defclass tile ()
  ((tile-type
    :initarg :tile-type
    :accessor tile-type
    :initform 'floor
    :documentation "Type of tile")
    (tile-contents
      :initarg :tile-contents
      :accessor tile-contents
      :initform '()
      :documentation "Any items the tile holds")
    (tile-hidden
      :initarg :tile-hidden
      :accessor tile-hidden
      :initform nil
      :documentation "Whether the tile is hidden or shown")
    (tile-locked
      :initarg :tile-locked
      :accessor tile-locked
      :initform nil
      :documentation "Whether the tile is locked")
    (tile-closed
      :initarg :tile-closed
      :accessor tile-closed
      :initform nil
      :documentation "Whether the tile is open or closed")))

打印方法：

(defmethod print-object ((object tile) stream)
  (with-slots (tile-type tile-contents tile-hidden tile-locked tile-closed) object
    (if tile-hidden
      (format stream " ")
      (let ((an-item (car tile-contents)))
        (if an-item
          (format stream "~a" an-item)
          (format stream (case tile-type
            ('wall "#")
            ('upstair "<")
            ('downstair ">")
            ('door (if tile-closed "+" "\\"))
            (otherwise " "))))))))

您不需要引用中的符号CASE.

实际上你不应该在中引用符号CASE条款。

See:

CL-USER 31 > (case 'quote
               ('not-quote 'oops-really-quote)
               ('quote 'it-is-a-quote))
OOPS-REALLY-QUOTE

以上是使用的意外后果'not-quote而不是正确的未引用的not-quote.

下列说法正确的是：

CL-USER 32 > (case 'quote
               (not-quote 'oops-really-quote)
               (quote 'it-is-a-quote))
IT-IS-A-QUOTE

Common Lisp 中 CASE 的语法

case keyform
  {normal-clause}*
  [otherwise-clause]

=> result*

normal-clause::= (keys form*) 
otherwise-clause::= ({otherwise | t} form*) 
clause::= normal-clause | otherwise-clause 
keys ::= object | (object*)

正如您所看到的，键要么是单个对象，要么是对象列表。不评估对象。

CASE 子句中的符号不​​被求值。

(case tile-type
  (wall ...)
  (door ...))

WALL and DOOR纯粹是符号，不作为变量进行计算。

Lisp 读者阅读'fooas (quote foo).

你写了：

(case tile-type
  ('wall ...)
  ('door ...))

这相当于：

(case tile-type
  ((quote wall) ...)
  ((quote door) ...))

但你不能引用一个符号CASE。您必须提供符号作为文字常量。

如果你写：

(let ((bar 'foo)
      (baz 'foo))
  (case bar
    (baz :we-have-a-foo-through-baz)
    (foo :we-really-have-a-foo)))

这返回:WE-REALLY-HAVE-A-FOO。因为CASE使用常量数据，而不是变量。

CASE接受项目列表。既然你有QUOTE作为 more than 子句中的符号，编译器显示警告。

正如我所说，不可能报价，因为这些物品没有经过评估。

As for CASE接受子句中的项目列表，如下所示：

(case tile-type
  ((door wall) ...)
  ((floor window painting) ...))

For the WALL符号，您需要在创建对象时确保它位于正确的包中。

最好使用关键字符号，例如:wall。这样您就不需要导出它，并且不会混淆该符号位于哪个包中。

关于代码的格式: 您有一个项目符号列表，紧随其后的是代码部分。这不会按照您的预期呈现。我在代码之前添加了文本“代码：”。然后渲染就按预期工作了。