如何获取 clojure 嵌套结构中给定键的所有值

(def threads
  {:values
   [{:_id "t1"
     :u {:uid 1}
     :members {:values [{:uid 1} {:uid 2}]}
     :messages {:values
                [{:_id "m1" :u {:uid 1}}
                 {:_id "m2" :u {:uid 2}}]}}
    {:_id "t2"
     :u {:uid 12}
     :members {:values [{:uid 11} {:uid 12}]}
     :messages {:values
                [{:_id "m3" :u {:uid 13}}
                 {:_id "m4" :u {:uid 12}}]}}]})

需要找出键 :uid 的所有值 在这种情况下，答案应该返回 [1 2 11 12 13] 而不使用任何全局绑定。需要任何级别的嵌套结构的解决方案规模。

Thanks

这可以通过树序列和过滤器或后步行来完成。这两种方法对我来说都很有趣：

树序列：

user> (map :uid 
           (filter #(if (and (map? %) (:uid %)) true  false)  
                   (tree-seq #(or (map? %) (vector? %)) identity threads)))
(1 2 1 1 2 13 12 12 11 12) 

用螺纹穿出时看起来更好->>（并使用 set 和 vec 删除重复项）

user> (->> (tree-seq #(or (map? %) (vector? %)) identity threads) 
           (filter #(if (and (map? %) (:uid %)) true  false)) 
           (map :uid)  
           set 
           vec)                                
[1 2 11 12 13] 

或与后行走：

user> (let [results (atom [])]
        (clojure.walk/postwalk
           #(do (if-let [uid (:uid %)] (swap! results conj uid)) %)
           threads)
         @results)
[1 2 1 1 2 13 12 12 11 12]

这使用一个函数遍历结构，如果结构包含名为 :uid 的键，则将其附加到本地原子。然后最后返回原子的累积内容。这与您的示例略有不同，因为它会累积重复项。如果你想有效地消除它们，那么使用集合作为累加器而不是向量，然后在最后将其转换为向量（你的示例有向量结果）

user> (let [results (atom #{})] 
         (clojure.walk/postwalk 
            #(do (if-let [uid (:uid %)] (swap! results conj uid)) %) 
            threads) 
         (vec @results))
[1 2 11 12 13]