Question

我想知道是否可以awk独自闯入 一个日志文件，然后有awk输出一条不同的消息 小时细分 (00-23) 以及该特定时间的计数 小时与不同的消息。

Example

请求的输出

Message1
00 13
01 30
...
23 6

Message2
00 50
01 10
...
23 120
etc, etc

输入文件看起来有点像下面这样：

blah,blah
2016-06-24 00:30:54 blah Message1 7 rand rand2
2016-06-24 00:40:12 blah Message2 35 rand rand2
2016-06-24 00:42:15 blah Message2 12 rand rand2
2016-06-24 00:58:01 blah Message1 5 rand rand2
2016-06-24 00:58:12 blah Message2 3 rand rand2
2016-06-24 01:02:25 blah Message2 2 rand rand2
2016-06-24 01:02:30 blah Message1 3 rand rand2
2016-06-24 01:05:14 blah Message1 10 rand rand2
2016-06-24 01:30:56 blah Message2 5 rand rand2
2016-06-24 01:55:41 blah Message2 3 rand rand2
blah, blah

请注意，这是一个虚构的输入文件。

要获取此输入文件请求的输出，我知道我需要print $4然后在新线上做类似的事情print substr($2,1,2)" "sum[$5]。同样的时间同样的时间$4我必须添加$4在一起了。

Code

另请注意，我必须使用awk3.1.7 所以我不能做任何花哨的新东西awk 4.1.0+.

我知道如何获得不同的信息。

{
msg[$4]++
}
END {
  for (m in msg) {
     print m;
   }
}

要返回小时，我可以做以下事情：

{
msg[$4]++
hr[$4] = substr($2,1,2)
}
END {
  for (m in msg) {
     print m;
     print hr[m];
   }
}

最后，总和是这样的：

{
msg[$4]++
hr[$4] = substr($2,1,2)
sum[$4] += $5
}
END {
  for (m in msg) {
     print m;
     print hr[m]" "sum[m];     
   }
}

非常感谢任何和所有的帮助。

你会想要这样的东西：

$ cat tst.awk
BEGIN { FS="[ :]" }
{ sum[$6,$2]+=$7; msgs[$6]; hrs[$2] }
END {
    for (msg in msgs) {
        print msg
        for (hr in hrs) {
            print hr, sum[msg,hr]+0
        }
        print ""
    }
}

$ awk -f tst.awk file
Message1
00 12
01 13

Message2
00 50
01 10

但显然这有点猜测，因为它是针对您发布的示例输入运行的，但您没有提供相关的预期输出。

顺便说一句，问题主题行AWK - Is it possible...，假设它是关于操纵文本，那么该问题的答案始终是“是”，因此无需询问是否可能。

我刚刚注意到你之前的问题，你说时间可能并不总是出现在你的数据中，所以这可能是你真正想要的：

$ cat tst.awk
BEGIN { FS="[ :]" }
{ sum[$6,$2+0]+=$7; msgs[$6] }
END {
    for (msg in msgs) {
        print msg
        #for (hr=0; hr<=23; hr++) {
        for (hr=0; hr<=4; hr++) {
            printf "%02d %d\n", hr, sum[msg,hr]
        }
        print ""
    }
}
$
$ awk -f tst.awk file
Message1
00 12
01 13
02 0
03 0
04 0

Message2
00 50
01 10
02 0
03 0
04 0

显然将“4”更改为“23”。我还建议您考虑使用 CSV 输出，以便可以导入到 Excel 等，例如：

$ cat tst.awk
BEGIN { FS="[ :]"; OFS="," }
{ sum[$6,$2+0]+=$7; msgs[$6] }
END {
    printf "hr"
    for (msg in msgs) {
        printf "%s%s", OFS, msg
    }
    print ""
    for (hr=0; hr<=4; hr++) {
        printf "%02d", hr
        for (msg in msgs) {
            printf "%s%d", OFS, sum[msg,hr]
        }
        print ""
    }
}

$ awk -f tst.awk file
hr,Message1,Message2
00,12,50
01,13,10
02,0,0
03,0,0
04,0,0

$ awk -f tst.awk file | column -s, -t
hr  Message1  Message2
00  12        50
01  13        10
02  0         0
03  0         0
04  0         0