Inno Setup 获取目录大小（包括子目录）

我正在尝试编写一个返回目录大小的函数。我编写了以下代码，但它没有返回正确的大小。例如，当我在{pf}它返回 174 字节的目录，这显然是错误的，因为该目录的大小有多个千兆字节。这是我的代码：

function GetDirSize(DirName: String): Int64;
var
  FindRec: TFindRec;
begin
  if FindFirst(DirName + '\*', FindRec) then
    begin
      try
        repeat
          Result := Result + (Int64(FindRec.SizeHigh) shl 32 + FindRec.SizeLow);
        until not FindNext(FindRec);
      finally
        FindClose(FindRec);
      end;
    end
  else
    begin
      Result := -1;
    end;
end;

我怀疑FindFirst函数不包含子目录，这就是为什么我没有得到正确的结果。因此，如何返回正确的目录大小，即包括所有子目录中的所有文件，与在 Windows 资源管理器中选择文件夹上的属性相同？我在用FindFirst因为该函数需要支持超过 2GB 的目录大小。

The FindFirst确实包含子目录，但它不会告诉你它们的大小。

您必须递归到子目录并逐个文件计算文件的总大小，类似于例如Inno Setup：在代码部分递归复制文件夹、子文件夹和文件.

function GetDirSize(Path: String): Int64;
var
  FindRec: TFindRec;
  FilePath: string;
  Size: Int64;
begin
  if FindFirst(Path + '\*', FindRec) then
  begin
    Result := 0;
    try
      repeat
        if (FindRec.Name <> '.') and (FindRec.Name <> '..') then
        begin
          FilePath := Path + '\' + FindRec.Name;
          if (FindRec.Attributes and FILE_ATTRIBUTE_DIRECTORY) <> 0 then
          begin
            Size := GetDirSize(FilePath);
          end
            else
          begin
            Size := Int64(FindRec.SizeHigh) shl 32 + FindRec.SizeLow;
          end;
          Result := Result + Size;
        end;
      until not FindNext(FindRec);
    finally
      FindClose(FindRec);
    end;
  end
    else
  begin
    Log(Format('Failed to list %s', [Path]));
    Result := -1;
  end;
end;

For Int64， 你需要Inno Setup 的 Unicode 版本，在任何情况下你应该使用什么。只有当您有充分的理由坚持使用 Ansi 版本时，您才可以替换Int64 with Integer，但限制为 2 GB。