Hive 相对于同一表中的其他数组列对数组列进行排序

我在 hive 有一个表，有 2 列col1 array<int> and col2 array<double>。输出如下图

col1                col2
[1,2,3,4,5]         [0.43,0.01,0.45,0.22,0.001]

我想按升序对这个 col2 进行排序，并且 col1 也应该相应地更改其索引，例如

col1                col2
[5,2,4,3,1]        [0.001,0.01,0.22,0.43,0.45]

分解两个数组，排序，然后再次聚合数组。使用sort在之前的子查询中collect_list对数组进行排序：

with your_data as(
select array(1,2,3,4,5) as col1,array(0.43,0.01,0.45,0.22,0.001)as col2
)

select original_col1,original_col2, collect_list(c1_x) as new_col1, collect_list(c2_x) as new_col2
from
(
select d.col1 as original_col1,d.col2 as original_col2, c1.x as c1_x, c2.x as c2_x, c1.i as c1_i  
 from your_data d
      lateral view posexplode(col1) c1 as i,x
      lateral view posexplode(col2) c2 as i,x
where c1.i=c2.i 
distribute by original_col1,original_col2
sort by c2_x
)s
group by original_col1,original_col2;

Result:

OK
original_col1   original_col2                   new_col1        new_col2
[1,2,3,4,5]     [0.43,0.01,0.45,0.22,0.001]     [5,2,4,1,3]     [0.001,0.01,0.22,0.43,0.45]
Time taken: 34.642 seconds, Fetched: 1 row(s)

编辑：同一脚本的简化版本，您可以不用第二个poseexplode，使用按位置直接引用d.col2[c1.i] as c2_x

with your_data as(
select array(1,2,3,4,5) as col1,array(0.43,0.01,0.45,0.22,0.001)as col2
)

select original_col1,original_col2, collect_list(c1_x) as new_col1, collect_list(c2_x) as new_col2
from
(
select d.col1 as original_col1,d.col2 as original_col2, c1.x as c1_x, d.col2[c1.i] as c2_x, c1.i as c1_i  
 from your_data d
      lateral view posexplode(col1) c1 as i,x
distribute by original_col1,original_col2
sort by c2_x
)s
group by original_col1,original_col2;