Power BI - 查找前后的匹配百分比（赏金 100）假设分析

我有一个要求，我有一张这样的桌子，

Role              Skills
Developer           C
Developer           SQL
Developer           C++
Data Analyst        R
Data Analyst        Python
Data Analyst        SQL
Business Analyst    Excel
Business Analyst    SQL

我需要在 Power BI 中创建类似的东西，

解释 Power BI Visual Table 中业务分析师的第一个结果，

1. 从筛选器 1 中 - 我选择了数据分析师 - 其实际技能是 R、Python 和 SQL
2. 从筛选器 2 - 我选择了一项新技能 (Upskill) 作为 Excel。

所以现在他有4个技能。

对于业务分析师来说 - 可视表中的第 1 行 无需提升技能的技能百分比 - 只有来自数据分析师的 SQL 技能与业务分析师技能相匹配，因此在提升技能之前为 50%。

但在使用 Excel 进行技能提升后，它就成为 100% 的业务分析师技能。

技能提升后，他拥有 4 项技能，但其中 2 项（R 和 Python），他不会在业务分析师角色中使用。这显示在表的最后一列中。

我的想法是试图展示 - 所选角色的技能组与另一个角色匹配的百分比有多少。

提升技能后，所选角色的技能组与另一个角色匹配的百分比有多少。

很高兴能够基于此创建新表并根据需要重新调整数据。

这里的关键是为切片器提供不同的不相关表。

让我们调用你的原始表Jobs.

创建两个新表：

Role = DISTINCT(Jobs[Role])
Skills = DISTINCT(Jobs[Skills])

现在我们有了这些表，我们可以用它们创建切片器并将所选值读入我们的度量中。

% Skill Match =
VAR SelectedRole = SELECTEDVALUE ( Role[Role] )
VAR RelatedSkills = CALCULATETABLE ( DISTINCT ( Jobs[Skills] ), Jobs[Role] = SelectedRole )
VAR CurrentSkills = DISTINCT ( Jobs[Skills] )
RETURN
    DIVIDE (
        COUNTROWS ( INTERSECT ( RelatedSkills, CurrentSkills ) ),
        COUNTROWS ( CurrentSkills )
    )

这将读取您在第一个变量中选择的角色。当我们提高技能时，我们也会在另一个切片器中读取：

% Skill Match Upskilled =
VAR SelectedRole = SELECTEDVALUE ( Role[Role] )
VAR SelectedSkills = VALUES ( Skills[Skills] )
VAR RelatedSkills = CALCULATETABLE ( DISTINCT ( Jobs[Skills] ), Jobs[Role] = SelectedRole )
VAR CurrentSkills = DISTINCT ( Jobs[Skills] )
VAR Upskilled = DISTINCT ( UNION ( RelatedSkills, SelectedSkills ) )
RETURN
    DIVIDE (
        COUNTROWS ( INTERSECT ( Upskilled, CurrentSkills ) ),
        COUNTROWS ( CurrentSkills )
    )

未使用的技能测量非常相似。

Unused Skills =
VAR SelectedRole = SELECTEDVALUE ( Role[Role] )
VAR SelectedSkills = VALUES ( Skills[Skills] )
VAR RelatedSkills = CALCULATETABLE ( DISTINCT ( Jobs[Skills] ), Jobs[Role] = SelectedRole )
VAR CurrentSkills = DISTINCT ( Jobs[Skills] )
VAR Upskilled = DISTINCT ( UNION ( RelatedSkills, SelectedSkills ) )
RETURN
    CONCATENATEX ( EXCEPT ( Upskilled, CurrentSkills ), Jobs[Skills], ", " )

结果应该是这样的：

您可以添加一些逻辑来隐藏您在矩阵视觉中选择的角色，但我在这里让事情变得更简单。