通过ExternalProject_Add 使用 pybind11 进行 CMake 项目的智能方法

我正在使用编写一个 python 模块pybind11 with CMake3.9.4. 因为方便所以想下载pybind11源文件使用ExternalProject_Add in my CMakeLists.txt.

当我跑步时cmake .，它不下载pybind11源文件，并抛出错误。

CMake Error at CMakeLists.txt:21 (add_subdirectory):
  The source directory
    /Users/me/foo/pybind11_external-prefix/src/pybind11_external
  does not contain a CMakeLists.txt file.

CMake Error at CMakeLists.txt:22 (pybind11_add_module):
  Unknown CMake command "pybind11_add_module".

有一个解决方法：

1. 注释掉 CMakeLists.txt 中的最后 3 行
2. run cmake .
3. run make（然后，它下载pybind11源文件）
4. 恢复 CMakeLists.txt 中的最后 3 行
5. run cmake .
6. run make

然而，这并不聪明……有什么办法可以下载吗？pybind11 using ExternalProject_Add无需注释掉这些行并恢复它们（并且无需运行cmake and make twice)?

/Users/me/foo/CMakeLists.txt

cmake_minimum_required(VERSION 3.8)
project(foo)
set(CMAKE_CXX_STANDARD 14)

include(ExternalProject)
ExternalProject_Add(
        pybind11_external
        GIT_REPOSITORY https://github.com/pybind/pybind11.git
        GIT_TAG v2.2.1
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
)
set(PYBIND11_CPP_STANDARD -std=c++14)
ExternalProject_Get_Property(pybind11_external source_dir)
include_directories(${source_dir}/include)

add_subdirectory(${source_dir})             # comment out, then restore this line
pybind11_add_module(foo SHARED foo.cpp)     # comment out, then restore this line
add_dependencies(foo pybind11_external)     # comment out, then restore this line

/用户/me/foo/foo.hpp

#ifndef FOO_LIBRARY_H
#define FOO_LIBRARY_H

#include<pybind11/pybind11.h>

int add(int i, int j);

#endif

/用户/我/foo/foo.cpp

#include "foo.hpp"

int add(int i, int j) {
    return i + j;
}

PYBIND11_MODULE(example, m) {
    m.doc() = "pybind11 example plugin";
    m.def("add", &add, "A function which adds two numbers");
}

使用 CMake 的获取内容 https://cliutils.gitlab.io/modern-cmake/chapters/projects/fetch.html模块（版本 3.11+），你可以这样做：

include(FetchContent)
FetchContent_Declare(
    pybind11
    GIT_REPOSITORY https://github.com/pybind/pybind11
    GIT_TAG        v2.2.3
)

FetchContent_GetProperties(pybind11)
if(NOT pybind11_POPULATED)
    FetchContent_Populate(pybind11)
    add_subdirectory(${pybind11_SOURCE_DIR} ${pybind11_BINARY_DIR})
endif()

这将在配置时下载 pybind11，并且add_subdirectory它。然后你就可以打电话了pybind11_add_module.