MainFormOnTaskbar + 工具提示导致焦点窃取

我使用 Delphi XE2 构建了下面的代码。它创建 Form1，Form1 立即创建 Form2 的实例。当我按下 Form2 上的按钮时，会创建第二个 Form2。

现在，如果我将鼠标悬停在第二个、最上面的 Form2 上的按钮上，并等待工具提示出现，工具提示出现的那一刻，firstForm2 出现在最前面，抢尽了焦点。

仅当出现此问题时Application.MainFormOnTaskbar is True。它还依赖于从 Form1 创建的第一个 Form2FormCreate方法。如果我使用PostMessage()延迟创建第一个 Form2 直到应用程序完成初始化，问题就消失了。

我想了解为什么会发生这种情况。我已经了解到Delphi的Application对象处理很多事情，包括提示显示，并且我知道Delphi可以在初始化期间重新创建窗口的句柄，但我无法遵循这一点来完全解释上述行为（或事实上上述两个事实是否相关）。

项目1.dpr

program Project1;

uses
  Vcl.Forms,
  Unit1 in 'Unit1.pas' {Form1},
  Unit2 in 'Unit2.pas' {Form2};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True; // False makes problem go away
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

Unit1.pas

unit Unit1;
interface
uses
  Vcl.Forms, Unit2;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  public
    procedure CreateForm2;
  end;

var
  Form1: TForm1;

implementation
{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  CreateForm2;
end;

procedure TForm1.CreateForm2;
var
  frm : TForm2;
begin
  frm := TForm2.Create(Application); // (Could pass Self - makes no difference)
  frm.Show;
end;

end.

Unit2.pas

unit Unit2;
interface
uses
  Vcl.Forms, System.Classes, Vcl.Controls, Vcl.StdCtrls, WinApi.Windows;

type
  TForm2 = class(TForm)
    Button1: TButton; // This button has a hint
    procedure Button1Click(Sender: TObject);
  end;

var
  Form2: TForm2;

implementation
uses
  System.SysUtils, Unit1;

{$R *.dfm}

procedure TForm2.Button1Click(Sender: TObject);
begin
  Form1.CreateForm2;
end;

end.

这里的关键问题是第一个实例TForm2创建为应用程序窗口拥有的窗口，Application.Handle。这里我指的是Windows 所有者的含义 http://msdn.microsoft.com/en-us/library/windows/desktop/ms632599.aspx#owned_windows。在 VCL 语言中，这称为弹出父级。

现在，当你第一次创建它时TForm2例如，Application.MainForm财产仍在nil。并且因为你没有明确分配PopupParent，代码在TCustomForm.CreateParams将所有者设置为应用程序窗口。

您只是不希望您的窗口被隐藏的应用程序窗口所拥有。这就是为什么首先TForm2实例有时出现在所有其他窗口后面，特别是在主窗体后面。它只是由错误的所有者创建的。

拥有的表格Application.Handle出现在THintWindow.ActivateHint。发生这种情况是由于读取的行ParentWindow := Application.Handle。接下来是调用SetWindowPos(Handle, ...)这会导致错误拥有的表单出现在前面。大概该表格出现在前面是因为它也属于Application.Handle。现在我还没有对精确机制的明确解释，但我觉得这不是很有趣，因为表单显然设置错误。

无论如何，根本问题是您创建了一个不正确拥有的窗口。因此，解决方案是确保正确拥有该窗口。通过分配来做到这一点PopupParent。例如：

procedure TForm1.CreateForm2;
var
  frm : TForm2;
begin
  frm := TForm2.Create(Application); // (Could pass Self - makes no difference)
  frm.PopupParent := Self;
  frm.Show;
end;