如何编写一个计算表达式生成器来累积值并允许标准语言构造？

我有一个计算表达式生成器，可以随时生成值，并且有许多自定义操作。但是，它不允许标准 F# 语言构造，并且我在弄清楚如何添加此支持方面遇到了很多麻烦。

举一个独立的例子，下面是一个非常简单且毫无意义的构建 F# 列表的计算表达式：

type Items<'a> = Items of 'a list

type ListBuilder() =
    member x.Yield(()) = Items []

    [<CustomOperation("add")>]
    member x.Add(Items current, item:'a) =
        Items [ yield! current; yield item ]

    [<CustomOperation("addMany")>]
    member x.AddMany(Items current, items: seq<'a>) =
        Items [ yield! current; yield! items ]

let listBuilder = ListBuilder()

let build (Items items) = items

我可以用它来构建列表：

let stuff =
    listBuilder {
        add 1
        add 5
        add 7
        addMany [ 1..10 ]
        add 42
    } 
    |> build

然而，这是一个编译器错误：

listBuilder {
    let x = 5 * 39
    add x
}

// This expression was expected to have type unit, but
// here has type int.

这也是：

listBuilder {
    for x = 1 to 50 do
        add x
}

// This control construct may only be used if the computation expression builder
// defines a For method.

我已经阅读了我能找到的所有文档和示例，但有些东西我没有得到。每一个.Bind() or .For()我尝试的方法签名只会导致越来越多令人困惑的编译器错误。我可以找到的大多数示例要么在您进行过程中建立一个值，要么允许常规的 F# 语言构造，但我还没有找到一个能够同时完成这两者的示例。

如果有人可以通过向我展示如何采用此示例并在构建器中添加支持来为我指明正确的方向let绑定和for循环（至少 -using, while and try/catch那就太好了，但如果有人让我开始，我可能可以弄清楚这些），然后我将能够感激地将课程应用于我的实际问题。

最好看的地方是spec http://research.microsoft.com/en-us/um/cambridge/projects/fsharp/manual/spec.html#_Toc335818835。例如，

b {
    let x = e
    op x
}

被翻译成

   T(let x = e in op x, [], fun v -> v, true)
=> T(op x, {x}, fun v -> let x = e in v, true)
=> [| op x, let x = e in b.Yield(x) |]{x}
=> b.Op(let x = e in in b.Yield(x), x)

因此，这表明了问题所在，尽管它没有提供明显的解决方案。清楚地，Yield需要泛化，因为它需要采用任意元组（基于范围内的变量数量）。也许更微妙的是，它还表明x不在调用范围内add（请参阅未绑定的x作为第二个参数b.Op？）。为了允许您的自定义运算符使用绑定变量，它们的参数需要具有[<ProjectionParameter>]属性（并从任意变量中获取函数作为参数），并且您还需要设置MaintainsVariableSpace to true如果您希望绑定变量可供以后的操作员使用。这会将最终翻译更改为：

b.Op(let x = e in b.Yield(x), fun x -> x)

由此看来，似乎没有办法避免在每个操作之间传递一组绑定值（尽管我很想被证明是错误的）——这将需要您添加一个Run方法在最后删除这些值。将它们放在一起，您将得到一个如下所示的构建器：

type ListBuilder() =
    member x.Yield(vars) = Items [],vars

    [<CustomOperation("add",MaintainsVariableSpace=true)>]
    member x.Add((Items current,vars), [<ProjectionParameter>]f) =
        Items (current @ [f vars]),vars

    [<CustomOperation("addMany",MaintainsVariableSpace=true)>]
    member x.AddMany((Items current, vars), [<ProjectionParameter>]f) =
        Items (current @ f vars),vars

    member x.Run(l,_) = l