该表达式的类型为 int，但此处与 unit 类型一起使用

我试图在 F# 中获得与此 vb.net 代码完全相同的（非功能性的）：

Function FastPow(ByVal num As Double, ByVal exp As Integer) As Double
   Dim res As Double = 1
   If exp < 1 Then
      If exp = 0 Then Return res
      exp = -exp
      num = 1 / num
   End If
   Do While exp > 1
      If exp Mod 2 = 1 Then 
         res = res * num
      num = num * num
      exp = exp >> 1
   Loop
   Return res * num
End Function

我写了这个：

let FastPow num exp =
   let mutable ex = exp
   let mutable res = 1
   let mutable n = num
   if ex < 1 then
      if ex = 0 then res
      ex <- -ex
      n <- 1 / n
   while ex > 1 do
      if (ex % 2 = 1) then 
         res <- res * n
      n <- n * n
      exp >>> 1
   res * n

但在 res 的“if ex = 0 then res”行中我收到错误：
“该表达式具有 int 类型，但此处与 unit 类型一起使用”。 我不明白为什么它会给我这个错误。
编辑：我实际上也收到了警告：
“这个表达式的类型应该是‘unit’，但是却是‘int’类型。”
在“如果（例如％2 = 1）那么”

在 F# 中，函数的返回值是函数中计算的最后一个表达式。那么，让我们重点关注以下几点：

   if ex < 1 then
      if ex = 0 then res    (* <--- this is not an early return *)
      ex <- -ex             (* <--- F# evaluates this code after the *)
      n <- 1 / n            (*      if statement *)

此外，if 语句具有返回值，该返回值也恰好是 if 语句中执行的最后一个值。如果 if 语句不是函数的返回值，则它应该具有返回类型unit。请注意，变量赋值的返回类型为unit.

我们需要重写您的代码以适应您的提前返回，因此我们可以这样做：

let FastPow2 num exp =
    if exp = 0 then 1
    else
        let mutable ex = exp
        let mutable res = 1
        let mutable n = num
        if ex < 1 then
            ex <- -ex
            n <- 1 / n
        while ex > 1 do
            if (ex % 2 = 1) then  (* still have a bug here *)
                res <- res * n
            n <- n * n
            exp >>> 1  (* <--- this is not a variable assignment *)
        res * n

尽管我认为 F# 在错误的位置报告了错误，但我们仍然存在一个错误。表达方式exp >>> 1返回一个 int，它不分配任何变量，因此它不等同于原始 C# 代码。我认为你的意思是使用ex变量代替。我们可以按如下方式修复您的代码：

let FastPow2 num exp =
    if exp = 0 then 1
    else
        let mutable ex = exp
        let mutable res = 1
        let mutable n = num
        if ex < 1 then
            ex <- -ex
            n <- 1 / n
        while ex > 1 do
            if (ex % 2 = 1) then 
                res <- res * n
            n <- n * n
            ex <- ex >>> 1
        res * n

现在你的功能已经固定了，但它真的很难看。让我们将其转换为更惯用的 F#。您可以用模式匹配替换 if 语句，并用递归替换 while 循环：

let FastPow2 num exp =
    match exp with 
    | 0 -> 1
    | _ ->
        let rec loop ex res n =
            if ex > 1 then
                let newRes = if ex % 2 = 1 then res * n else res
                loop (ex >>> 1) newRes (n * n)
            else res * n

        let ex, n = if exp < 1 then (-exp, 1 / num) else (exp, num)
        loop ex 1 n

好多了！还有一些空间可以美化这个功能，但你明白了:)