VBA 代码中的 Excel 公式

所以，在 Sheet1 中，我有一些名称的基础，它看起来像这样：

在 Sheet2 中，我正在使用 Sheet1 中的这些名称。我这样做的方式是在 A 列中输入代码值，在 B 列中输入名称，在 C 列中输入姓氏。看起来像这样：

我已经用公式完成了此操作，将其输入到公式栏中。对于 A 列（或名称），我使用了以下公式：=IFERROR(VLOOKUP(A2;Sheet1!A:C;2;FALSE);"")对于 B 列（或姓氏），我使用了这个：=IFERROR(VLOOKUP(A2;Sheet1!A:C;3;FALSE);"")。我已将这些公式拖到第 20 行，效果非常好。

现在，我想做的是将这些公式放入 Excel VBA 代码中，并使它们适用于指定的范围。我刚刚开始使用VBA，我不知道如何在其中执行此操作，尝试了一些方法但不起作用，...，到目前为止我已经做到了。我对 Excel/宏/VBA 很陌生，所以任何帮助将不胜感激。

如果您输入以下代码，则以下代码将起作用Code值在sheet2并突出显示它们，然后运行此宏：

Selection.Offset(0, 1).FormulaR1C1 = "=IFERROR(VLOOKUP(RC[-1],Sheet1!C[-1]:C,2,FALSE),"""")"
Selection.Offset(0, 2).FormulaR1C1 = "=IFERROR(VLOOKUP(RC[-2],Sheet1!C[-2]:C,3,FALSE),"""")"
Selection.Offset(0, 1).Value = Selection.Offset(0, 1).Value
Selection.Offset(0, 2).Value = Selection.Offset(0, 2).Value

Edit:如果您想在键入时更新值，请使用（感谢@PeterAlbert 的额外优化！）：

Private Sub Worksheet_Change(ByVal Target As Range)

    'end if the user made a change to more than one cell at once?
    If Target.Count > 1 Then End

    'stop system activating worksheet_change event while changing the sheet
    Application.EnableEvents = False

    'continue if column 1(A) was updated
    'and
    'dont continue if header or row 1 was changed
    If Target.Column = 1 And Target.Row <> 1 Then

        With Target.Offset(0, 1) 'alter the next cell, current column +1 (column B)

            'RC1 = current row and column 1(A) e.g. if A2 was edited, RC1 = $B2
            'C1:C2 = $A:$B
            .FormulaR1C1 = "=IFERROR(VLOOKUP(RC1,Sheet1!C1:C2,2,FALSE),"""")"
            .Value = .Value 'store value
        End With

        With Target.Offset(0, 2) 'alter the next cell, current column +2 (column C)

            'C1:C3 = $A:$C
            .FormulaR1C1 = "=IFERROR(VLOOKUP(RC1,Sheet1!C1:C3,3,FALSE),"""")"
            .Value = .Value 'store value
        End With

    End If

    Application.EnableEvents = True 'reset system events
End Sub

RC的解释：

The FormulaR1C1当引用当前单元格的单元格时，可以很好地使用公式类型。有一些规则需要记住：

• The R代表行和C用于 Column 及其后面的整数（如果有）定义行或列；
• 作为基础RC公式引用自身；
• 后面的任何数字R or C包装成[]是其自身的偏移量，例如如果你在牢房里A1并使用R[1]C[1]你会引用单元格B2;
• 也可以是以下任意数字R and C是一个精确的，例如如果你参考R2C2无论您所在的单元格也会指向B2; and

如果你在牢房里，事情就会变得复杂C5，例如使用Range("C5").FormulaR1C1 =并编码如下：

1. "=RC[-1]"参考单元格B5
2. "=RC1"参考单元格A5，更正确的是$A5
3. "=R[1]C[-2]"参考单元格A6
4. "=Sum(C[-1]:C5)" is =Sum(B:E)，更正确的是=Sum(B:$E)