带有 wsdl2java 插件的 gradle

我正在使用 no.nils.wsdl2java 插件，完整的 gradle.build 文件如下所示：

plugins {
    id 'org.springframework.boot' version '2.3.4.RELEASE'
    id 'io.spring.dependency-management' version '1.0.12.RELEASE'
    id 'java'
    id "no.nils.wsdl2java" version "0.10"
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

configurations {
    jaxb
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}
dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.oracle.database.jdbc:ojdbc8'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    implementation group: 'com.oracle.ojdbc', name: 'orai18n', version: '19.3.0.0'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'com.google.code.gson:gson:2.8.5'
}

tasks.named('test') {
    useJUnitPlatform()
}
wsdl2java {
    generatedWsdlDir = file("build/generated/wsdl/Service")
    wsdlsToGenerate = [
            ['-p', 'Service', '-wsdlLocation', 'classpath:wsdl/Service.wsdl',
             '-autoNameResolution', "src/main/resources/wsdl/Service.wsdl"]
    ]
}

当我使用 gradle jvm 版本 11 构建项目时，出现异常：

无法加载类“jakarta.xml.bind.JAXBException”。

** 但在版本 8 上出现错误：

org/apache/cxf/tools/wsdlto/WSDLToJava 已由更新版本的 Java 运行时（类文件版本 55.0）编译，该版本的 Java 运行时仅识别最高版本为 52.0 的类文件。

我知道关于javax -> jakarta命名空间迁移但如何解决我的问题？

在你的 build.gradle 中添加以下内容：

wsdl2javaExt {
    cxfVersion = "3.5.5"
}

显式指定 Apache CXF 版本。它应该可以正确地使用 Java 8 进行编译。

嗯，错误说的是org/apache/cxf/tools/wsdlto/WSDLToJava使用 Java 11 编译，但您的项目使用 Java 8。该类由wsdl2java plugin:

 def wsdlToJava = classLoader.loadClass("org.apache.cxf.tools.wsdlto.WSDLToJava").newInstance()

它是 Apache CXF 项目的一部分。要查看它来自哪里，您可以打印依赖关系树：

./gradlew app:dependencies --configuration wsdl2java

在结果中你可以发现：

+--- org.apache.cxf:cxf-tools-wsdlto-databinding-jaxb:+ -> 4.0.0
...
|    +--- org.apache.cxf:cxf-tools-wsdlto-core:4.0.0

的版本org.apache.cxf:cxf-tools-wsdlto-databinding-jaxb被设定为+，所以gradle使用最新版本，目前是4.0.0。该插件在这些行中添加了此依赖项：

            // add cxf as dependency
            project.dependencies {
                wsdl2java "org.apache.cxf:cxf-tools-wsdlto-databinding-jaxb:$cxfVersion"

$cxfVersion默认设置为+，但您可以使用以下代码在 build.gradle 中覆盖它：

wsdl2javaExt {
    cxfVersion = "3.5.5"
}

使用以前的 Apache CXF 版本（与 Java 8 兼容）