从 Word VBA 编辑工作簿（无论打开还是关闭）

我正在尝试在 Word 中编写宏，以便可以将一些信息保存到计算机其他位置的 Excel 文件中。为此我写了这个：

Dim exlApp As Object
Dim exlWbk As Object
Set exlApp = CreateObject("Excel.Application")
Set exlWbk = exlApp.Workbooks.Open(FileName:="D:\database.xlsx")
exlWbk.ActiveSheet.Cells(1, 1).Value = "some info"
exlWbk.Close SaveChanges:=True
Set exlWbk = Nothing
exlApp.Quit
Set exlApp = Nothing

该代码对我来说工作得很好，除非用户已经打开了相关的 Excel 文件 (database.xlsx)。在这种情况下，运行宏将提示我将新更改保存到 Excel 文件的新副本中，这不是我想要的。我希望将新更改包含在当前 Excel 文件中，而不创建它的第二个副本。

由于上面的代码存在一些问题，我这样写：

Dim exlApp As Object
Dim exlWbk As Object
Set exlApp = CreateObject("Excel.Application")
Set exlWbk = exlApp.GetObject("D:\database.xlsx")
exlWbk.ActiveSheet.Cells(1, 1).Value = "some info"
exlWbk.Save
Set exlWbk = Nothing
exlApp.Quit
Set exlApp = Nothing

但一切都没有改变。我知道有一些方法可以确定我的 Excel 文件是否打开，但问题是，如果我发现该文件已打开，我不知道如何更改我的代码。

如何确定工作簿是否在 Excel 中打开以便可以对其进行编辑，或者如果文件已关闭则打开该文件以便对其进行编辑？

根据文档 https://learn.microsoft.com/en-us/office/vba/language/reference/user-interface-help/getobject-function, GetObject(filename)如果现有文件已打开，则将拾取该文件；如果文件未打开，则可以选择打开该文件：

当执行此代码时，与该关联的应用程序 启动指定路径名，指定文件中的对象 活性。

如果 Excel 未运行，则默认情况下什么都看不到GetObject(filename)执行。 Excel 将被打开，文件将被打开并更改。因此，存在一个真正的危险，即 Excel 实例和工作簿将“挂起”在内存中，这可以在 Windows“任务管理器”中看到。重复运行此类代码最终可能会使 Windows 崩溃，因此必须小心在每次迭代时正确清理内容。

由于该问题还规定该文件可能已被用户打开，因此有必要确定这一点以及 Excel 应用程序是否已在运行。

以下代码示例演示了如何完成此操作。假设应用程序和文件都没有打开。然后它测试 Excel 是否已在运行。

Set xlApp = GetObject(, "Excel.Application")

请注意语法上的差异：而不是fileName有一个逗号，后跟应用程序的名称。这将检查应用程序是否可用；如果不是，则会触发错误。所以，On Error Resume Next先于GetObject，这意味着错误将被忽略。

由于忽略错误是危险的，所以下一行Or Error GoTo 0重新打开错误。

If GetObject不成功，变量xlApp无法实例化，其“值”是Nothing. If Not xlApp Is Nothing执行如果xlApp可以被实例化并且布尔值appAlreadyOpen设置为 true 以便我们知道not代码完成后退出 Excel。它还检查所需的工作簿是否已打开。如果是，xlWb可以实例化并将 fileAlreadyOpened 设置为 true。

If xlWb无法实例化，因为 Excel 应用程序未运行或工作簿尚未打开，GetObject(fileName)被执行。工作簿将在现有 Excel 实例（如果已运行）或新的 Excel 实例中打开。在此代码块的末尾有两行注释：如果新启动的 Excel 应用程序可见并在代码结束时保持打开状态，请取消注释它们。

然后可以编辑工作簿。

最后，事情需要清理。检查布尔值，如果不正确，则关闭工作簿和可能的应用程序。很重要最后两行从内存中释放这些对象。如果代码创建任何其他对象，例如Ranges，这些也应该被释放，按照它们实例化的相反顺序。

Sub GetFileOpenedOrClosed()
    Dim xlApp As Object              ' Excel.Application
    Dim xlWB As Object, wb As Object ' Excel.Workbook
    Dim fileName As String
    Dim fileAlreadyOpen As Boolean, appAlreadyOpen As Boolean

    fileName = "C:\Test\SampleChart.xlsx"
    fileAlreadyOpen = False
    appAlreadyOpen = False
    On Error Resume Next
    Set xlApp = GetObject(, "Excel.Application")
    On Error GoTo 0
    If Not xlApp Is Nothing Then
        appAlreadyOpen = True
        For Each wb In xlApp.Workbooks
            If wb.FullName = fileName Then
                Set xlWB = wb
                fileAlreadyOpen = True
                Exit For
            End If
        Next
    End If
    If xlWB Is Nothing Then
        Set xlWB = GetObject(fileName)
        Set xlApp = xlWB.Application
        xlWB.Windows(1).Visible = True 'So that the window is not hidden when file is opened again
        'xlApp.Visible = True
        'xlApp.UserControl = True
    End If
    xlWB.Worksheets(1).Cells(7, 1).value = "some other info"
    If Not fileAlreadyOpen Then
        xlWB.Save
        xlWB.Close
    End If
    If Not appAlreadyOpen Then
        xlApp.Quit
    End If
    Set xlWB = Nothing
    Set xlApp = Nothing
End Sub