delphi中如何用鼠标移动圆圈？

delphi中如何用鼠标移动圆圈？

circle:Shape;

请务必使用以下命令将从控件上的 MouseMove 获得的鼠标 X,Y 客户端坐标转换为父级客户端坐标：ClientToScreen and ScreenToClient.

以下过程将控件的中心移动到其客户端坐标中的点 (X,Y)：

procedure MoveControl(AControl: TControl; const X, Y: Integer);
var
  lPoint: TPoint;
begin
  lPoint := AControl.Parent.ScreenToClient(AControl.ClientToScreen(Point(X, Y)));
  AControl.Left := lPoint.X - AControl.Width div 2;
  AControl.Top := lPoint.Y - AControl.Height div 2;
end;

现在，要在单击 TShape 时移动 TShape，您必须提供以下 MouseMove 事件处理程序：

procedure TForm1.ShapeToMoveMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
  if ssLeft in Shift then // only move it when Left-click is down
    MoveControl(Sender as TControl, X, Y);
end;

要测试它，请使用以下代码在表单中放置一个按钮：

procedure TForm1.ButtonTestClick(Sender: TObject);
begin
  with TShape.Create(nil) do
  begin
    Name := Format('ShapeToMove%d',[Self.ControlCount + 1]);
    Parent := Self; // Parent will free it
    Shape := stCircle;
    Width := 65;
    Height := 65;
    OnMouseMove := ShapeToMoveMouseMove;
  end;
end;

现在，这是一个极简的示例，但它应该可以帮助您入门。
为了好玩，只需使用此 MouseMove 事件处理程序挂钩其他控件...:-)