Prolog：消除查询中的重复

我一直在尝试编写一个简单的代码，其行为方式如下：

| ?- hasCoppiesOf(X,[a,b,a,b,a,b,a,b]).
X = [a,b] ? ;
X = [a,b,a,b] ? ;
X = [a,b,a,b,a,b,a,b] ? ;

And

| ?- hasCoppiesOf([a,b,a,b,a,b,a,b], X).    
X = [] ? ;    
X = [a,b,a,b,a,b,a,b] ? ;    
X = [a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b] ? ;    
X = ...

这个愿望导致了下一段代码：

hasCoppiesOf(A,[]).


hasCoppiesOf([H1|T1], [H1|T2]) :-
  append(T1, [H1], X),
  hasCoppiesOf([H1|T1], X, T2).


hasCoppiesOf(A, A, B) :-
  hasCoppiesOf(A, B).

hasCoppiesOf(A, [H1|T1], [H1|T2]) :-
  append(T1, [H1], X),
  hasCoppiesOf(A, X, T2).

它给了我第二个查询所需的内容，但是第一个查询的结果是：

?- hasCoppiesOf(X,[a,b,a,b,a,b,a,b]).
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b] ;
X = [a, b, a, b, a, b] ;
X = [a, b, a, b, a, b] ;
X = [a, b, a, b, a, b] ;
X = [a, b, a, b, a, b] ;
X = [a, b, a, b, a, b] ;

它似乎工作得很好，但重复相同的答案让我感到困扰。这可能是一个简单的错误，但是有没有办法让输出更漂亮呢？ 老实说，这是一个谜，为什么 Prolog 将两个相同的数组视为不同的答案。 或者也许只是我的系统出了问题？

编辑： 评论中的人的温柔指导帮助我解决了这个问题。然而，如果这个问题的读者是想要解决完全相同问题的人——代码不能很好地工作，我很抱歉。

我认为你只是让你的谓词变得比需要的更复杂，可能只是想得太多了。给定的解决方案可能会在逻辑的多个路径上取得成功。

你可以做到这一点，无需append/3通过对齐列表的前端并使原始列表在重复时“重置”：

% Empty list base cases
dups_list([], []).
dups_list([_|_], []).

% Main predicate, calling aux predicate
dups_list(L, Ls) :-
    dups_list(L, L, Ls).

% Recursive auxiliary predicate
dups_list([], [_|_], []).
dups_list([], [X|Xs], [X|Ls]) :-
    dups_list(Xs, [X|Xs], Ls).
dups_list([X|Xs], L, [X|Ls]) :-
    dups_list(Xs, L, Ls).

以下是一些结果：

| ?- dups_list(X,[a,b,a,b,a,b,a,b]).

X = [a,b] ? a

X = [a,b,a,b]

X = [a,b,a,b,a,b,a,b]

no
| ?- dups_list([a,b,a,b,a,b,a,b], X).

X = [] ? ;

X = [a,b,a,b,a,b,a,b] ? ;

X = [a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b] ? ;

X = [a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b,a,b] ?
...
| ?- dups_list(A, B).

A = []
B = [] ? ;

A = [_|_]
B = [] ? ;

A = [C]
B = [C] ? ;

A = [C]
B = [C,C] ? ;

A = [C,D]
B = [C,D] ? ;

A = [C]
B = [C,C,C] ? ;

A = [C,D,E]
B = [C,D,E] ? ;
...

可能有一种方法可以进一步简化解决方案，但我还没有充分利用它来确定是否是这种情况。