两个 Perl 脚本之间的 cgi 会话

我在我的网站中使用了两个 Perl 脚本。我在侧面有一个搜索字段，它调用第一个脚本，结果写入输出文件中。 下一次单击时，用户调用第二个脚本，该脚本读取输出文件并根据用户搜索构建配置文件。 目前我只在输出文件上写入，但我需要使用会话 ID 来个性化该文件。

我正在尝试使用 CGI::Session 进行此操作，但我不知道如何使用这两个 Perl 脚本进行此操作。我想我需要比较会话 ID，并为每个会话编写一个输出文件。

你们中有人知道如何做到这一点吗？

第一个脚本： 在将会话写入文件中：

my $session = new CGI::Session(undef, $cgi, {Directory=>"/usr/local/path/"});

然后向客户端发送cookie：

my $cookie = $cgi->cookie(CGISESSID => $session->id );

第二个脚本： 尝试获取会话 ID：

$sid = $cgi->cookie("CGISESSID") || undef;
print $sid 

它给出了一个Status: 500.

您需要将会话 ID 传递给客户端，以便客户端在以后的请求中将其返回给您。这通常是使用 cookie 来完成的。

use utf8;
use open ':std', ':encoding(UTF-8)';

use CGI          qw( -utf8 );
use CGI::Session qw( );

use constant SESSION_DIR    => '...';
use constant SESSION_EXPIRE => '+12h';  # From last use (not creation)

my $cgi = CGI->new();

my $session = CGI::Session->new(
   'driver:file',
   scalar($cgi->cookie('session_id')),
   { Directory => SESSION_DIR },
);
$session->expire(SESSION_EXPIRE);

# Whatever your page does
my $count = $session->param('count');
++$count;
$session->param(count => $count);
my $content = "This is request $count";

print
   $cgi->header(
      -type    => 'text/html',
      -charset => 'UTF-8',
      -cookie => $cgi->cookie(
         -name => 'session_id',
         -value => $session->id,
         -expires => SESSION_EXPIRE,
       ),
   ),
   $content;

这里只显示了一个脚本，但显然没有什么可以阻止两个脚本访问同一会话（如果它们可以访问同一会话存储）。