我可以在 Jenkinsfile 中增强 scm 吗？

我花了很长时间才明白什么checkout scm真正的意思是在 Jenkinsfile 中（checkout 是一个函数，scm 是一个默认的全局变量）。

现在我明白了，我想补充一下scm例如，增加特定结账的超时时间或设置sparseCheckoutPaths。这可能吗？如果是这样，怎么办？

对于 Git 来说，checkout scm基本上相当于：

checkout([
     $class: 'GitSCM',
     branches: scm.branches,
     doGenerateSubmoduleConfigurations: scm.doGenerateSubmoduleConfigurations,
     extensions: scm.extensions,
     userRemoteConfigs: scm.userRemoteConfigs
])

如果您想将稀疏结帐添加到现有的 scm，您要做的是：

checkout([
     $class: 'GitSCM',
     branches: scm.branches,
     doGenerateSubmoduleConfigurations: scm.doGenerateSubmoduleConfigurations,
     extensions: scm.extensions + [$class: 'SparseCheckoutPaths',  sparseCheckoutPaths:[[$class:'SparseCheckoutPath', path:'path/to/file.xml']]],
     userRemoteConfigs: scm.userRemoteConfigs
])

更好的是，您可以定义一个自定义步骤, sparseCheckout在共享库中。

def call(scm, files) {
    if (scm.class.simpleName == 'GitSCM') {
        def filesAsPaths = files.collect {
            [path: it]
        }

        return checkout([$class                           : 'GitSCM',
                         branches                         : scm.branches,
                         doGenerateSubmoduleConfigurations: scm.doGenerateSubmoduleConfigurations,
                         extensions                       : scm.extensions +
                                 [[$class: 'SparseCheckoutPaths', sparseCheckoutPaths: filesAsPaths]],
                         submoduleCfg                     : scm.submoduleCfg,
                         userRemoteConfigs                : scm.userRemoteConfigs
        ])
    } else {
        // fallback to checkout everything by default
        return checkout(scm)
    }
}

然后你用以下方式调用它：

sparseCheckout(scm, ['path/to/file.xml'])