如何将 HSB 转换为 RGB

我有一台德尔福XE2项目 https://stackoverflow.com/questions/17729550/how-can-you-change-the-font-color-using-timer-control改变Label01 Font Color using Timer04。所以我写了以下代码：

procedure TMainForm.FormCreate(Sender: TObject);
begin
  Timer04.Enabled := true;
end;
..
..
..
..
..
procedure TMainForm.Timer04Timer(Sender: TObject);
var
  StartColor, RedColor, GreenColor, BlueColor: integer;
begin
  StartColor := ColorToRGB(Label01.Font.Color);
  RedColor := GetRValue(StartColor);
  GreenColor := GetGValue(StartColor);
  BlueColor := GetBValue(StartColor);
  if RedColor <= 251 then Inc(RedColor, 1) else RedColor := 1;
  if GreenColor <= 252 then Inc(GreenColor, 2) else GreenColor := 2;
  if BlueColor <= 253 then Inc(BlueColor, 3) else BlueColor := 3;
  Label01.Font.Color := RGB(RedColor, GreenColor, BlueColor);
end;

该代码完美运行。Label01 Font Color不同颜色之间的变化。

现在我正在努力实现这一点Label02 Color将被固定（例如绿色），并且 Brightnees 的值将从0 to 100。如果该值达到100它将减少到0并且它将持续到一个循环。

对于我的情况，我选择了HUE=135, SATURATION=85 and BRIGHTNESS=50。的价值BRIGHTNESS将会增加自50 to 100然后将减少100 to 0并将继续下去。 但问题是没有这样的Function可转换HSB to RGB反之亦然Delphi XE2。我已经用谷歌搜索过了。但我已经找到任何Function as HSBToRGB。只有一些Delphi Unit可用。我读过他们的评论，发现每个人都有一些错误。

这是 Delphi 的 C 代码翻译，在这里找到：http://www.cs.rit.edu/~ncs/color/t_convert.html http://www.cs.rit.edu/~ncs/color/t_convert.html

function RGBFP(R, G, B: Double): TColor;
const
  RGBmax = 255;
begin
  Result := RGB(Round(RGBmax * R), Round(RGBmax * G), Round(RGBmax * B));
end;

function HSVtoRGB(H, S, V: Double): TColor;
var
  i: Integer;
  f, p, q, t: Double;
begin
  Assert(InRange(H, 0.0, 1.0));
  Assert(InRange(S, 0.0, 1.0));
  Assert(InRange(V, 0.0, 1.0));

  if S = 0.0 then
  begin
    // achromatic (grey)
    Result := RGBFP(V, V, V);
    exit;
  end;

  H := H * 6.0; // sector 0 to 5
  i := floor(H);
  f := H - i; // fractional part of H
  p := V * (1.0 - S);
  q := V * (1.0 - S * f);
  t := V * (1.0 - S * (1.0 - f));
  case i of
  0:
    Result := RGBFP(V, t, p);
  1:
    Result := RGBFP(q, V, p);
  2:
    Result := RGBFP(p, V, t);
  3:
    Result := RGBFP(p, q, V);
  4:
    Result := RGBFP(t, p, V);
  else
    Result := RGBFP(V, p, q);
  end;
end;

我已经进行了最低限度的测试。请随时仔细检查。