Excel 检测并跟踪任何工作表中的（值）变化

我已经设法编写了一个代码来检测任何工作表中特定单元格的值变化，但我一直在努力构建一些检测和跟踪范围（值）变化的代码。

例如，如果用户决定复制并粘贴某些范围的数据（假设超过 1 个单元格），宏将不会捕获它。用户选择一个范围，然后在仍选择范围的情况下手动将值输入到每个单元格中也是如此。

我当前的代码由 2 个宏构成，第一个宏在工作表选择发生更改时运行，并将 target.value 存储到先前的值变量中。第二个宏在工作表发生更改时运行，并测试目标值是否与前一个值不同，如果是，则通知用户已发生的更改。

好吧，我真的没有在这里看到任何涵盖整个事情的内容，所以这是一个粗略的尝试。

它将处理单单元或多单元更新（您可以设置一定的限制，超出该限制...）

它不会处理多区域（非连续）范围更新，但可以扩展以执行此操作。

您可能还应该添加一些错误处理。

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Where As String, OldValue As Variant, NewValue As Variant
    Dim r As Long, c As Long

    Dim rngTrack As Range

    Application.EnableEvents = False
    Where = Target.Address
    NewValue = Target.Value
    Application.Undo
    OldValue = Target.Value 'get the previous values
    Target.Value = NewValue
    Application.EnableEvents = True

    Set rngTrack = Sheets("Tracking").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)

    'multi-cell ranges are different from single-cell ranges
    If Target.Cells.CountLarge > 1 And Target.Cells.CountLarge < 1000 Then
        'multi-cell: treat as arrays
        For r = 1 To UBound(OldValue, 1)
        For c = 1 To UBound(OldValue, 2)
            If OldValue(r, c) <> NewValue(r, c) Then
                rngTrack.Resize(1, 3).Value = _
                  Array(Target.Cells(r, c).Address, OldValue(r, c), NewValue(r, c))
                Set rngTrack = rngTrack.Offset(1, 0)
            End If
        Next c
        Next r
    Else
        'single-cell: not an array
        If OldValue <> NewValue Then
            rngTrack.Resize(1, 3).Value = _
              Array(Target.Cells(r, c).Address, OldValue, NewValue)
            Set rngTrack = rngTrack.Offset(1, 0)
        End If
    End If

End Sub

获取先前值的“撤消”部分来自加里学生的回答：使用 VBA 如何检测工作表中的任何值何时发生变化？ https://stackoverflow.com/questions/30513655/using-vba-how-do-i-detect-when-any-value-in-a-worksheet-changes?rq=1