如何“newtype”IntSet？

谢谢newtype和GeneralizedNewtypeDeriving扩展，我们可以毫不费力地定义不同的轻量级类型：

newtype PersonId = PersonId Int deriving (Eq, Ord, Show, NFData, ...)
newtype GroupId  = GroupId Int deriving (Eq, Ord, Show, NFData, ...)

这允许类型系统确保PersonId不是偶然使用的GroupId符合预期，但仍然继承选定的类型类实例Int.

现在我们可以简单地定义PersonIdSet and GroupIdSet as

import Data.Set (Set)
import qualified Data.Set as Set

type PersonIdSet = Set PersonId
type GroupIdSet  = Set GroupId

noGroups :: GroupIdSet
noGroups = Set.empty

-- should not type-check
foo = PersonId 123 `Set.member` noGroups

-- should type-check
bar = GroupId 123 `Set.member` noGroups

这是类型安全的，因为映射是由键类型参数化的，而且，Set.member操作是多态的，所以我不需要定义每个 id 类型的变体，例如personIdSetMember and groupIdSetMember（以及我可能想要使用的所有其他设置操作）

...但是我怎样才能使用更有效的IntSets 代替PersonIdSet and GroupIdSet分别以与上面示例类似的方式？有没有一种简单的方法，无需将整个 Data.In Rest API 包装/复制为类型类？

我认为你必须包裹IntSet如你所说。但是，您可以引入幻像类型来创建一系列 ID 类型，而不是单独定义每个 ID 类型。IDs and IDSet彼此兼容的：

{-# LANGUAGE GeneralizedNewtypeDeriving #-}

import qualified Data.IntSet as IntSet
import Data.IntSet (IntSet)

newtype ID a = ID { unID :: Int }
              deriving ( Eq, Ord, Show, Num )

newtype IDSet a = IDSet { unIDSet :: IntSet }
              deriving ( Eq, Ord, Show )

null :: IDSet a -> Bool
null = IntSet.null . unIDSet

member :: ID a -> IDSet a -> Bool
member i = IntSet.member (unID i) . unIDSet

empty :: IDSet a
empty = IDSet $ IntSet.empty

singleton :: ID a -> IDSet a
singleton = IDSet . IntSet.singleton . unID

insert :: ID a -> IDSet a -> IDSet a
insert i = IDSet . IntSet.insert (unID i) . unIDSet

delete :: ID a -> IDSet a -> IDSet a
delete i = IDSet . IntSet.delete (unID i) . unIDSet

所以，假设你有一个Person类型，和一个Group输入，你可以这样做：

type PersonID = ID Person
type PersonIDSet = IDSet Person

type GroupID = ID Group
type GroupIDSet = IDSet Group