重命名并保存 Outlook 中的附件

我正在尝试使用 Outlook 规则保存附件并将其重命名为电子邮件正文中找到的单词。

该单词位于冒号之后的第三行。

我有一个规则集来运行这个脚本。

Public Sub saveAttachtoNet(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
saveFolder = "O:\EUROMKTG\Marketing Analytics Dept\Campaign 
Reporting\Campaign Dashboard\1. Exact Target (Salesforce Mrktg Cloud)"
 For Each objAtt In itm.Attachments
      objAtt.SaveAsFile saveFolder & "\" & objAtt.DisplayName
      Set objAtt = Nothing
 Next
End Sub

我会这样做：

Public Sub saveAttachtoNet(itm As Outlook.MailItem)
    Dim objAtt As Outlook.Attachment
    Dim saveFolder As String
    saveFolder = "O:\EUROMKTG\Marketing Analytics Dept" & _
                    "\Campaign Reporting\Campaign Dashboard" & _
                    "\1. Exact Target (Salesforce Mrktg Cloud)"

    Dim JobTxtInMail As String
    JobTxtInMail = "Exported for - JobID:"
    Dim StrStart As Integer
    StrStart = InStr(1, _
                    itm.Body, _
                    JobTxtInMail, _
                    vbTextCompare) + Len(JobTxtInMail) + 1
    Dim JobNum As String
    JobNum = Trim(Mid(itm.Body, _
                    StrStart, _
                    InStr(StrStart + 1, itm.Body, Chr(13)) - StrStart - 1))

    For Each objAtt In itm.Attachments
        objAtt.SaveAsFile saveFolder & "\" & JobNum & "__" & objAtt.DisplayName
        Set objAtt = Nothing
    Next objAtt
End Sub

你可能需要稍微调整一下+ 1 and - 1，分别在StrStart and JobNum.

并改变objAtt.SaveAsFile以适应所需的输出！