ORG指令后设置段寄存器

我目前正在关注操作系统开发教程 http://brokenthorn.com/Resources/OSDev4.html，其中包括有关引导加载程序的讨论。

我的引导加载程序当前处于 16 位实模式，因此，我能够使用提供的 BIOS 中断（例如 VGA 视频中断等）。

BIOS提供视频中断0x10（即视频电传打字机输出）。视频中断有功能0x0E，它允许我在屏幕上打印一个字符。

这是这个基本的引导加载程序：

org     0x7c00              ; Set program start (origin) address location at 0x7c00.
                            ; This program is loaded by the BIOS at 0x7c00.
bits    16                  ; We live in 16-bit Real Mode.

start:  
        jmp loader

bootmsg     db      "Welcome to my Operating System!", 0        ; My data string.

;-------------------------------------------------------
;   Description:    Print a null terminating string
;-------------------------------------------------------
print:
    lodsb                   ; Load string byte at address DS:SI and place in AL.
                            ; Then, increment/decrement SI as defined by the Direction Flag (DF) in FLAGS.
    or      al, al          ; Set the zero flag - is AL zero?
    jz      printdone       ; Check if this is the null byte
    mov     ah, 0eh
    int     10h
    jmp     print
printdone:
    ret

loader:
    ;|---------- Related to my question ----------|
        xor     ax, ax
        mov     ds, ax
        mov     es, ax
    ;|--------------------------------------------|

    mov     si, bootmsg
    call    print

    cli                     ; Clears all interrupts.
    hlt                     ; Halts the system.

times 510 - ($-$$) db 0    ; Make sure our bootloader is 512 bytes large. 

dw      0xAA55              ; Boot signature - Byte 511 is 0xAA and Byte 512 is 0x55, indicated a bootable disk.1

如上面的代码所示，我突出显示了以下三行：

xor     ax, ax
mov     ds, ax
mov     es, ax

根据原始消息来源，它是这样说的：

设置段以确保它们为 0。请记住，我们有 ORG 0x7c00。这意味着所有地址都基于 0x7c00:0。因为数据段位于同一代码段内，所以 null em。

我有一点困惑。据我了解，org指令告诉加载器在地址处加载该程序0x7c00。那我们为什么不以此作为我们的起始地址呢？这意味着，我们的两个重叠的数据和代码段是not位于一个基地址为零。这基地址应该是 0x7c0。为什么作者把基地址设置为0x0呢？

mov ax, 07c0h
mov dx, ax
mov es, ax

我一直在研究org更多说明和其他文档，我了解发生了什么。

根据NASM 文档 https://www.nasm.us/doc/nasmdoc7.html#section-7.1.1 on the org指令，缩写origin:

ORG指令的功能是指定NASM在程序加载到内存时假定程序开始的起始地址。 [...] NASM 的 ORG 完全按照指令所述执行：起源。它的唯一功能是指定一个偏移量，该偏移量将添加到该节内的所有内部地址引用中。

因此，NASM编译器假设程序将加载到原始指令指定的地址（即org）。 BIOS 正是这样做的。根据下列 https://wiki.osdev.org/Boot_Sequence，一旦 BIOS 找到包含有效引导签名的有效引导扇区，引导加载程序将“加载到内存0x0000:0x7c00处（段0，地址0x7c00）."

从上面的引用来看，当 NASM 文档说“内部地址引用”时，它指的是对代码中使用的具体内存区域的所有引用（例如引用标签等）。例如，上面的引导加载程序代码中的行：mov si, bootmsg将解决bootmsg to 0x07c00 + offset，其中偏移量由字符串的第一个字节的位置确定bootmsg（即“W”）。

使用上面的代码，如果我使用以下命令反汇编 bin 文件ndisasm实用程序 https://www.nasm.us/doc/nasmdoca.html我看到以下内容：

00000000  EB2C              jmp short 0x2e
00000002  57                
00000003  656C              
00000005  636F6D            
00000008  6520746F          
0000000C  206D79            
0000000F  204F70            
00000012  657261            
00000015  7469              
00000017  6E                
00000018  67205379          
0000001C  7374              
0000001E  656D              
00000020  2100              
00000022  AC                lodsb
00000023  08C0              or al,al
00000025  7406              jz 0x2d
00000027  B40E              mov ah,0xe
00000029  CD10              int 0x10
0000002B  EBF5              jmp short 0x22
0000002D  C3                ret
0000002E  31C0              xor ax,ax
00000030  8ED8              mov ds,ax
00000032  8EC0              mov es,ax
00000034  BE027C            mov si,0x7c02
00000037  E8E8FF            call 0x22
0000003A  FA                cli
0000003B  F4                hlt
00000...  ...               ...

（我删除了从0x00000002到0x00000020生成的指令，因为那是我的bootmsg字符串，代表数据，而不是代码）。

正如我们从输出汇编中看到的，在地址 0x00000034 处，我的bootmsg已替换为 0x7c02（例如 0x7c00 + 偏移量=0x02）。

迈克尔·佩奇 https://stackoverflow.com/questions/54045259/setting-segment-registers-after-org-instruction?noredirect=1#comment94930637_54045259也提供了一些非常扎实的见解。认为引导加载程序加载到 0x7c0:0x0000（段 0x07c0，偏移量 0）是一种常见的误解。尽管从技术上讲可以使用这一点，但它已被标准化为使用零段偏移量（一个好的做法是在引导扇区的最开始处强制执行 CS:IP https://wiki.osdev.org/Boot_Sequence）。正如 Michael 所提到的，如果需要更多信息，请查看以下第 4 节段偏移寻址指南 https://thestarman.pcministry.com/asm/debug/Segments.html.