“let”类陷入无限循环

请原谅代码中的任何愚蠢错误，因为这是我第一次尝试使用类，而且我在网上找不到任何真正将其放入其中的教程，really对于像我这样的傻瓜来说，简单的术语。我尽力遵循 MS 指南：https://msdn.microsoft.com/en-us/library/aa716315(v=vs.60).aspx https://msdn.microsoft.com/en-us/library/aa716315(v=vs.60).aspx，但我真的不明白我在做什么，这使得很难解释我应该改变什么。

我正在尝试创建一个存储三个数据、两个整数和一个字符串的类。我把它放在一个名为的类模块中tdata:

Sub tdata()

Dim tnumber As Integer, tacct As Integer
Dim ttype As String

Public Property Get t_acct() As Integer         'don't forget the account number!
    t_acct = tacct
End Property

Public Property Let t_acct(ByVal newval As Integer)
    t_acct = newval
End Property

Public Property Get t_numb() As Integer         'T1, T2, or T3 as applicable
    t_numb = tnumb
End Property

Public Property Let t_numb(ByVal newval As Integer)
    t_numb = newval
End Property

Public Property Get t_type() As String          'PF or MW
    t_type = ttype
End Property

Public Property Let t_type(ByVal newstr As String)
    t_type = newstr
End Property

End Sub

然后我在我的函数中调用它

Set t_info = New tdata
t_info.t_acct = wb2.Sheets(1).Cells(d, 1)             'd is just a row counter in a for loop
t_info.t_numb = Right(wb2.Sheets(1).Cells(d, 4), 1)
t_info.t_type = wb2.Sheets(1).Cells(d, 6)
references(CStr(wb2.Sheets(1).Cells(d, 5))).Add t_info

（当然，这不是全部代码，而只是调用它的部分）

我有Option Explicit所有这些有趣的东西都在，一切都编译得很好，但是当它到达函数片段的第二行时，它会尝试 maket_info.t_acct等于某物，它会走向Let为该功能发挥作用，并永远留在那里。具体来说，它在

Public Property Let t_acct(ByVal newval As Integer)
    t_acct = newval

永远。为什么是这样？我如何让它设置（错误，让）t_acct等于我想要的东西？

你的问题在这里：

Public Property Let t_acct(ByVal newval As Integer)
    t_acct = newval
End Property

那应该分配封装字段（tacct），而不是它本身。

我将向您提供我的秘诀：每当我创建新的类模块时，我都会从私有类型开始：

Option Explicit
Private Type TData 'assuming class module is named 'Data'
    Number As Integer
    Account As Integer
    AccountType As String
End Type

然后，我声明一个该类型的私有字段，名为this:

Private this As TData

有些人可能会争辩说this让一切变得如此混乱，因为this（私人领域）不是Me（对象实例）和其他语言this指的是对象实例和诸如此类的东西 - 如果它让您感到困惑，请给它任何您喜欢的名称（backing and encapsulated也完全没问题！）。

现在所有属性都变得清晰且一致：

Public Property Get Number() As Integer
    Number = this.Number
End Property

Public Property Let Number(ByVal value As Integer)
    this.Number = value
End Property

Public Property Get Account() As Integer
    Account = this.Account
End Property

Public Property Let Account(ByVal value As Integer)
    this.Account = value
End Property

Public Property Get AccountType() As String
    AccountType = this.AccountType
End Property

Public Property Let AccountType(ByVal value As String)
    this.AccountType = value
End Property

Property Get会员回归this.ThePropertyName, and Property Let会员assign this.ThePropertyName与提供的value- 总是。如果属性需要是非 get-only 的对象类型，您需要提供一个Property Set member:

Private Type TData
    '...
    SomeObject As Object
End Type
Private this As TData    

Public Property Get SomeObject() As Object
    Set SomeObject = this.SomeObject
End Property

Public Property Set SomeObject(ByVal value As Object)
    Set this.SomeObject = value
End Property

避免拆元音、前缀和不可读/无意义的名称，使用PascalCase对于公共成员，注重一致性，无论你做什么，都避免在公共类成员的名字中使用下划线 - 否则你想开始使用的那一天Implements是你的代码停止编译的那一天。遵循这一点，你的课程模块应该总是一目了然。