使用名称访问和禁用 ToolStripItems（ToolStripButtons、ToolStripMenuItems）

我想禁用名称存储在数据库中的 UI 元素（控件、组件等）。
我的代码适用于控件，但我想访问（以禁用它们）ToolStripItems，例如 ToolStripButtons、ToolStripMenuItems 等。

这是我当前的代码：

Dim df_command As New SqlCommand("select * from treftab where ref_data = 'INTERVENTION' and ref_code  = '0'", sfacon)
Dim df_reader As SqlDataReader = df_command.ExecuteReader

If df_reader.HasRows Then
    While df_reader.Read
        Dim reftext As String = df_reader("ref_text")
        Dim someVariable As Control = Nothing
        Dim SearchedControls = Me.Controls.Find(key:=reftext, searchAllChildren:=True)
        someVariable = SearchedControls(0)
        someVariable.Enabled = False
    End While
End If

您无法在 Form.Control 集合中找到 ToolStrip 或 MenuStrip 项，因为这些 UI 元素不是控件，而是特殊类型的组件。
虽然 ToolStrip 和 MenuStrip 都继承自 Control，但 ToolStripMenuItems 继承自 Component 并工具栏项 https://learn.microsoft.com/en-us/dotnet/api/system.windows.forms.toolstripitem（后者提供了Enabled财产）。

你可以建立一个Dictionary(Of String, Boolean)包含要启用或禁用的 UI 元素的名称，具体取决于您拥有的数据源中存储的值。

使用读取当前表单字段的方法，循环KeyValuePairs在字典中查找与字典匹配的元素Keys并设置Enable根据相应的属性Values.

例如，要禁用集合中的所有元素：
（我假设您已在数据源中存储了每个表单的所有不同名称）

Dim names As New Dictionary(Of String, Boolean)()    

' [...]
While df_reader.Read()
    names.Add(df_reader("ref_text").ToString(), False)
End While

EnableDisableFormElements(Me, names)

使用方法类型.GetFields() https://learn.microsoft.com/en-us/dotnet/api/system.type.getfields要查找指定 Form 的所有非公共实例字段，FieldInfo.GetValue() https://learn.microsoft.com/en-us/dotnet/api/system.reflection.fieldinfo.getvalue获取该 Field 表示的 UI 元素的实例。

然后，它确定 UI 元素是 Control 还是 ToolStripItem（从这些基类继承的 UI 元素具有Enabled属性）并使用存储在字典中的值来设置它。

TrimStart("_"c)是因为 VB.Net 有（IMO）坏习惯，在这些字段名称中添加下划线。使用 C# 不会发生这种情况。

Imports System.Reflection
Imports System.Windows.Forms

Private Sub EnableDisableFormElements(parentForm As Form, elementNames As Dictionary(Of String, Boolean))
    Dim allFields = parentForm.GetType().GetFields(BindingFlags.NonPublic Or BindingFlags.Instance)

    For Each element As KeyValuePair(Of String, Boolean) In elementNames
        Dim searchElement = allFields.FirstOrDefault(
        Function(f) f.Name.TrimStart("_"c).Equals(element.Key)).GetValue(parentForm)

        If searchElement IsNot Nothing Then
            If TypeOf searchElement Is Control Then
                DirectCast(searchElement, Control).Enabled = element.Value
            ElseIf TypeOf searchElement Is ToolStripItem Then
                DirectCast(searchElement, ToolStripItem).Enabled = element.Value
            End If
        End If
    Next
End Sub