加载动态 .ini 标识符

我正在创建我的学生计划表的虚拟版本，它基本上可以让你记下你有哪些科目的作业。

Here is the interface:

用户从组合框中选择主题并在相邻的备忘录中输入一些注释。完成后，他们将单击“保存”按钮，将其保存到 .ini 文件中。所选日期将成为部分名称，主题将成为标识符，备忘录中的文本将成为每个标识符的值。

Note:有 7 个可能的科目。

我的问题是在选择日期时加载组合框和备忘录，因为每个日期的标识符总是不同的。

例如：

2月16日用户输入（界面）：

英语 - 阅读小说的第 127 页。
数学 - 完成第 6 章。

对于 2 月 16 日，它在 .ini 文件中将如下所示：

[12年2月16日]
英语=阅读小说的第127页。
数学=完成第 6 章。

2月20日用户输入（界面）：

SOSE - 阅读教科书。
法律研究 - 填写在线调查。

2 月 20 日，它在 .ini 文件中将如下所示：

[2012年2月20日]
SOSE=阅读课本。
法律研究=填写在线调查。

现在您会看到，如果用户选择 2 月 16 日来查看他们的任务，则无法加载，因为每个标识符都不同。

是否有更好的 .ini 文件替代方案？我怎样才能实现这一目标？

您可以使用TIniFile.ReadSections获取各个日期，以及TIniFile.ReadSection获取该部分中的各个项目。这是一个简单的例子：

// Sample ini file

[16/02/12]
English=Read up to page 127 of novel.
Maths=Complete chapter 6. 

[20/02/12]
SOSE=Read textbook.
Legal Studies=Fill in online survey. 

Code:

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, IniFiles;

type
  TForm2 = class(TForm)
    ListBox1: TListBox;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure ListBox1Click(Sender: TObject);
  private
    { Private declarations }
    FIni: TMemIniFile;
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

const
  IniName = 'd:\Temp\SampleNotes.ini';

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FIni.Free;
end;

procedure TForm2.FormCreate(Sender: TObject);
begin
  FIni := TMemIniFile.Create(IniName);
  Memo1.Lines.Clear;
  FIni.ReadSections(ListBox1.Items);
end;

procedure TForm2.ListBox1Click(Sender: TObject);
var
  Section: string;
begin
  if ListBox1.ItemIndex > -1 then
  begin
    Section := ListBox1.Items[ListBox1.ItemIndex];
    FIni.ReadSection(Section, Memo1.Lines);
  end;
end;

end.

上面的结果是：