使用 Delphi Tokyo 10.2 通过 GetObjectProp 获取 TextSettings.Font.Style 属性

我使用Delphi的GetObjectProp函数来获取表单组件的属性，我获取了几个组件的所有属性，但是我无法获取TLabel等组件的TextSettings.Font.Style（粗体，斜体，...）属性例如。我需要知道组件文本是粗体还是斜体。我正在尝试获取这些属性的过程如下：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  TextSettings: TTextSettings;
  Fonte: TFont;
  Estilo: TFontStyle;
  Componente_cc: TControl; 
begin
Componente_cc := TControl(Label1);
if IsPublishedProp(Componente_cc, 'TextSettings') then
    begin
      TextSettings := GetObjectProp(Componente_cc, 'TextSettings') as TTextSettings;
        if Assigned(TextSettings) then
           Fonte := GetObjectProp(TextSettings, 'Font') as TFont;
        if Assigned(Fonte) then
           Estilo := GetObjectProp(Fonte, 'Style') as TFontStyle; // <-- error in this line 
        if Assigned(Estilo) then
           Edit1.text := GetPropValue(Estilo, 'fsBold', true);
    end
end; 

我在上面标记的行上显示的错误是。

[dcc64 错误] uPrincipal.pas(1350): E2015 运算符不适用于此操作数类型

我究竟做错了什么？

GetObjectProp(Fonte, 'Style')不会工作，因为Style首先不是一个基于对象的属性，它是一个Set基于属性。和GetPropValue(Estilo, 'fsBold', true)完全是错误的（并不是说你无论如何都可以调用它），因为fsBold不是财产，它是成员TFontStyle枚举。要检索Style属性值，你必须使用GetOrdProp(Fonte, 'Style'), GetSetProp(Fonte, 'Style'), or GetPropValue(Fonte, 'Style')相反（作为integer, string, or variant， 分别）。

话虽如此，一旦您检索到TextSettings对象，您根本不需要使用 RTTI 来访问它Font.Style属性，直接访问属性即可。

试试这个：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  Componente_cc: TControl;
  TextSettings: TTextSettings;
begin
  Componente_cc := ...;
  if IsPublishedProp(Componente_cc, 'TextSettings') then
  begin
    TextSettings := GetObjectProp(Componente_cc, 'TextSettings') as TTextSettings;
    Edit1.Text := BoolToStr(TFontStyle.fsBold in TextSettings.Font.Style, true);
  end;
end; 

更好（也是首选）的解决方案是根本不使用 RTTI。 FMX 类具有TextSettings物业还实施ITextSettings http://docwiki.embarcadero.com/Libraries/en/FMX.Graphics.ITextSettings正是针对这种情况的接口，例如：

procedure Tfrm1.aoClicarComponente(Sender: TObject);
var
  Componente_cc: TControl;
  Settings: ITextSettings;
begin
  Componente_cc := ...;
  if Supports(Componente_cc, ITextSettings, Settings) then
  begin
    Edit1.Text := BoolToStr(TFontStyle.fsBold in Settings.TextSettings.Font.Style, true);
  end;
end; 

阅读 Embarcadero 的文档了解更多详细信息：

在 FireMonkey 中设置文本参数 http://docwiki.embarcadero.com/RADStudio/en/Setting_Text_Parameters_in_FireMonkey