Gnuplot 极坐标直方图

我有一个数据文件file.dat平面上的点有三列（无线电、角度、温度），我想使用极坐标和颜色图将此数据绘制为直方图，如下图所示，但使用 gnuplot。我可以创建一个histogram.dat文件包含我想要的 bin 的值，但我不知道如何在 gnuplot 中绘制它

据我所知，gnuplot 中没有立即的“极地热图”绘图样式（但我可能是错的，至少，我没有在演示页面上看到示例）。因此，您必须自己实施。

基本上，对于每个数据点，您必须绘制一个填充段。因此，对于每个数据点，您必须在此单个线段的圆周上创建点。然后你可以绘制这一段with filledcurves和特定的颜色。

假设：

• 数据位于规则网格/角度步长（astep）和半径（rstep).
• 数据位于数据块中（如何将其从文件中获取到数据块中，请参阅gnuplot：将数据文件 1:1 加载到数据块中 https://stackoverflow.com/q/54600172/7295599)
• 分隔符是空格
• 没有标题行

进一步优化潜力：

• 自动提取astep and rstep.

我希望您可以根据您的需要调整代码。

Code:

### workaround for polar heatmap
reset session

set size square
set angle degrees
unset border
unset tics
set cbtics
set polar
set border polar
unset raxis

# create some test data
f(a,r) = r*cos(a) * r*sin(a) + rand(0)*100
set print $Data
    do for [a=0:350:10] {
        do for [r=1:20] {
            print sprintf("%g %g %g",a,r,f(a,r))
        }
    }
set print

astep = 10
rstep = 1

# create the segments for each datapoint
set print $PolarHeatmap
    do for [i=1:|$Data|] {
        a = real(word($Data[i],1))
        r = real(word($Data[i],2))
        c = real(word($Data[i],3))
        do for [j=-5:5] {
            print sprintf("%g %g %g",a+j*astep/10., r-0.5*rstep, c)
        }
        do for [j=5:-5:-1] {
            print sprintf("%g %g %g",a+j*astep/10., r+0.5*rstep, c)
        }
        print ""
        print ""
    }
set print

set style fill noborder
set palette defined (0 "blue", 1 "grey", 2 "green")

plot $PolarHeatmap u 1:2:3 w filledcurves palette notitle
### end of code

Result: