您可以在 Mojolicious Web 框架之外使用 Mojo 模板 - 我曾经这样做来为我的博客呈现静态页面。但是,那Mojo::Template
默认情况下不附带普通助手。相反,Mojolicous 的其余部分将变量和助手注入到模板中。
对于我的博客,我决定实现自己的帮助系统。我将在本答案的其余部分中描述我的解决方案。 Mojo 可能同时发生了变化,并且可能更喜欢一些不同的解决方案。
我将模板建模为一对stash引用和 Mojo::Template 对象。每个模板都被编译成它自己的包。稍后,我们可以将临时值注入到存储引用中并将值传递给外部。助手是特定存储引用的闭包,因此它可以在不使用显式参数的情况下访问这些值。
以下是模板的编译方式:
package AMON::Blog::TemplateCollection;
sub add_template($self, $name, $source) {
state $namespace_id = 0;
my $namespace = Package::Stash->new(
__PACKAGE__ . '::Namespace::' . ++$namespace_id);
my $template = Mojo::Template->new(
name => $name,
namespace => $namespace->name,
auto_escape => 1,
tag_start => '{{',
tag_end => '}}',
);
# enter the helpers into the namespace
my $stash_ref = \{};
while (my ($name, $code) = each %{ $self->helpers }) {
$namespace->add_symbol('&' . $name => $code->($stash_ref));
}
$template->parse($source);
$self->templates->{$name} = {
stash_ref => $stash_ref,
template => $template
};
return;
}
这里有一个layout
将请求的布局写入存储变量的帮助器:
layout => sub ($stash_ref) {
return sub ($name, %args) {
if (my $existing = $$stash_ref->{layout}) {
croak sprintf q(Can't change layout from "%s" to "%s"), $existing->{name}, $name;
}
$$stash_ref->{layout} = { name => $name, args => \%args };
};
},
外部接头仅用于关闭$stash_ref
,并在上面的模板编译期间执行。
为了渲染模板,我们提供临时存储值,然后处理 Mojo::Template。如果存储包含布局参数,我们会递归以当前模板的输出作为内容来渲染布局模板:
sub render($self, $name, %args) {
my $template = $self->templates->{$name}
// croak qq(Unknown template "$name");
my ($stash_ref, $template_object) = @$template{qw/stash_ref template/};
$$stash_ref = {
name => $name,
layout => undef,
args => \%args,
};
my $result = $template_object->process();
my $layout_args = $$stash_ref->{layout};
$$stash_ref = undef;
if (blessed $result and $result->isa('Mojo::Exception')) {
die $result;
}
if ($layout_args) {
my $name = $layout_args->{name};
my $args = $layout_args->{args};
return $self->render($name, %$args, content => $result);
}
return $result;
}
这种方法并不是非常优雅,但它不需要引入 Mojolicious 的所有其余部分(特别是控制器,这对于静态站点来说毫无意义)就可以工作。一段时间后,我切换到另一个模板引擎,它支持开箱即用的模板继承,而无需如此广泛的解决方法。