删除 Vim 中除正则表达式匹配之外的所有内容

我的具体案例是一个包含大量文本和 IPv4 地址的文本文档。我想删除除 IP 地址之外的所有内容。

我可以用:vglobal寻找([0-9]{1,3}\.){3}[0-9]{1,3}并删除所有没有IP地址的行，但之后我只知道如何搜索整行并选择匹配的文本。有更容易的方法吗。

简而言之，我正在寻找一种无需使用外部程序（如 grep）即可执行以下操作的方法：

grep --extended-regexp --only-matching --regexp="([0-9]{1,3}\.){3}[0-9]{1,3}"

从 vim 调用 grep 可能需要调整我的正则表达式（例如：删除 \v）。使用 vim 的增量搜索表明我的模式是正确的，并且我不想在 grep 中验证我的正则表达式。

Edit:感谢彼得，这是我现在使用的功能。 （C 是我通常在函数中破坏的寄存器。）

"" Remove all text except what matches the current search result
"" The opposite of :%s///g (which clears all instances of the current search).
function! ClearAllButMatches()
    let old = @c
    let @c=""
    %s//\=setreg('C', submatch(0), 'l')/g
    %d _
    put c
    0d _
    let @c = old
endfunction

Edit2:我将其设置为接受范围的命令（但默认为整个文件）。

"" Remove all text except what matches the current search result. Will put each
"" match on its own line. This is the opposite of :%s///g (which clears all
"" instances of the current search).
function! s:ClearAllButMatches() range
    let is_whole_file = a:firstline == 1 && a:lastline == line('$')

    let old_c = @c

    let @c=""
    exec a:firstline .','. a:lastline .'sub//\=setreg("C", submatch(0), "l")/g'
    exec a:firstline .','. a:lastline .'delete _'
    put! c

    "" I actually want the above to replace the whole selection with c, but I'll
    "" settle for removing the blank line that's left when deleting the file
    "" contents.
    if is_whole_file
        $delete _
    endif

    let @c = old_c
endfunction
command! -range=% ClearAllButMatches <line1>,<line2>call s:ClearAllButMatches()

这种效果可以通过使用 sub-replace-special 替换和setreg()逐行

:let @a=""
:%s//\=setreg('A', submatch(0), 'l')/g
:%d _
:pu a
:0d _

或全部在一行中：

:let @a=""|%s//\=setreg('A', submatch(0), 'l')/g|%d _|pu a|0d _

概述：使用替换将每个匹配逐行附加到寄存器“a”中，然后用寄存器“a”的内容替换整个缓冲区

解释：

1. let @a=""清空我们将要附加到的“a”寄存器
2. %s//\=setreg('A', submatch(0), 'l')/g使用最后一个模式进行全局替换
3. the \=expr将用表达式的内容替换模式
4. submatch(0)获取刚刚匹配的整个字符串
5. setreg('A', submatch(0), 'l')将匹配的字符串附加（注意：大写“a”）到@a，但是逐行
6. %d _删除黑洞寄存器中的每一行（又名@_）
7. pu a将@a的内容放入缓冲区
8. 0d _删除第一行

担忧：

• 这会毁掉你的一个寄存器。这个例子毁了@a
• 使用最后的搜索模式。尽管您可以使用您想要的任何模式修改替换命令：%s/<pattern>/\=setreg('A', submatch(0), 'l')/g

如需更多帮助

:h :s\=
:h :let-@
:h submatch()
:h setreg()
:h :d
:h :p