将本地时间转换为 UTC 时，如何使 Time::Piece 尊重 DST？

我想将时间戳从当地时间转换为 GMT。我有遗留代码“手动”执行此操作Time::Local::timelocal() and gmtime。它有效，但我不喜欢它并想使用Time::Piece反而。我用了这个答案 https://stackoverflow.com/a/411795/5830574这样做（尽管他们正在以相反的方式转换，但我能够替换+ with - :-)).

这是我的代码：

#!/usr/bin/env perl

use strict;
use warnings;
use Time::Local;
use Time::Piece;
use POSIX qw(strftime);

sub local_to_utc_timelocal
{
    my $local_ts = shift;
    my ( $year, $mon, $mday, $hour, $min, $sec ) 
        = ( $local_ts =~ /(\d\d)-(\d\d)-(\d\d) (\d\d):(\d\d):(\d\d)/ );
    my $local_secs = Time::Local::timelocal( $sec, $min, $hour, $mday, $mon - 1, $year );
    return POSIX::strftime( '%y-%m-%d %H:%M:%S', gmtime($local_secs) );
}

sub local_to_utc_timepiece
{
    my $local_ts = shift;
    my $local_tp = Time::Piece->strptime( $local_ts, '%y-%m-%d %H:%M:%S' );
    my $utc_tp   = $local_tp - localtime->tzoffset(); # ***
    return $utc_tp->strftime('%y-%m-%d %H:%M:%S');
}

my $local;

# DST in effect (April 19 2016):
$local = '16-04-19 14:30:00';
print "DST in effect:\n";
printf("utc(%s) = %s (using timelocal)\n", $local, local_to_utc_timelocal($local));
printf("utc(%s) = %s (using timepiece)\n\n", $local, local_to_utc_timepiece($local));

# DST NOT in effect (Feb 19 2016):
$local = '16-02-19 14:30:00';
print "DST NOT in effect:\n";
printf("utc(%s) = %s (using timelocal)\n", $local, local_to_utc_timelocal($local));
printf("utc(%s) = %s (using timepiece)\n", $local, local_to_utc_timepiece($local));

不幸的是，Time::Piece 代码似乎无法在 DST 下正常工作。我住在德国，所以目前（春季/夏季，DST 生效）我们采用 UTC+2。对于“2016 年 4 月 19 日”，上面的代码给出：

DST in effect:
utc(16-04-19 14:30:00) = 16-04-19 12:30:00 (using timelocal)
utc(16-04-19 14:30:00) = 16-04-19 12:30:00 (using timepiece)

哪个是对的。但对于“2016 年 2 月 19 日”（当我们处于 UTC+1 时），相同的代码给出：

DST NOT in effect:
utc(16-02-19 14:30:00) = 16-02-19 13:30:00 (using timelocal)
utc(16-02-19 14:30:00) = 16-02-19 12:30:00 (using timepiece)

那就是gmtime(Time::Local::timelocal($timestamp))给出正确的 1 小时偏移，同时Time::Piece仍然给予2小时的补偿。

这是一个错误吗Time::Piece还是我用错了？

我知道有很多方法可以将当地时间转换为 UTC，但我想使用Time::Piece因为它的简单性。另外我不能使用DateTime因为这需要将其部署在十几台生产机器上。

问题1

localtime现在返回，所以localtime->tzoffset()暂时返回偏移量。改变

my $utc_tp = $local_tp - localtime->tzoffset();

to

my $utc_tp = $local_tp - $local_tp->tzoffset();

然而，这留下了$utc_tp标记为当地时间，所以你真的想要：

my $utc_tp = gmtime( $local_tp->epoch );

问题2

尽管它的名字，$local_tp不是当地时间，所以$local_tp->tzoffset()为零。改变

Time::Piece->strptime( $local_ts, '%y-%m-%d %H:%M:%S' )

to

localtime->strptime( $local_ts, '%y-%m-%d %H:%M:%S' );