在 awk 中，如何将包含多个格式字符串的文件与 printf 一起使用？

我有一个例子，我想使用文件的输入作为格式printf()在 awk 中。当我将其设置在代码中的字符串中时，我的格式有效，但当我从输入加载它时，它不起作用。

这是问题的一个小例子：

$ # putting the format in a variable works just fine:
$ echo "" | awk -vs="hello:\t%s\n\tfoo" '{printf(s "bar\n", "world");}'
hello:  world
        foobar
$ # But getting the format from an input file does not.
$ echo "hello:\t%s\n\tfoo" | awk '{s=$0; printf(s "bar\n", "world");}'
hello:\tworld\n\tfoobar
$ 

所以......格式替换有效（“%s")，但不是制表符和换行符等特殊字符。知道为什么会发生这种情况吗？有没有办法“做一些事情”来输入数据以使其可用作格式字符串？

更新#1：

作为进一步的示例，请考虑使用 bash heretext 进行以下操作：

[me@here ~]$ awk -vs="hello: %s\nworld: %s\n" '{printf(s, "foo", "bar");}' <<<""
hello: foo
world: bar
[me@here ~]$ awk '{s=$0; printf(s, "foo", "bar");}' <<<"hello: %s\nworld: %s\n"
hello: foo\nworld: bar\n[me@here ~]$

据我所知，多个不同的 awk 解释器都会发生同样的情况，并且我无法找到任何解释原因的文档。

更新#2：

我试图替换的代码目前看起来像这样，在 shell 中带有嵌套循环。目前，awk 是only被用于其printf，并且可以替换为基于 shell 的printf:

#!/bin/sh

while read -r fmtid fmt; do
  while read cid name addy; do
    awk -vfmt="$fmt" -vcid="$cid" -vname="$name" -vaddy="$addy" \
      'BEGIN{printf(fmt,cid,name,addy)}' > /path/$fmtid/$cid
  done < /path/to/sampledata
done < /path/to/fmtstrings

输入示例为：

## fmtstrings:
1 ID:%04d Name:%s\nAddress: %s\n\n
2 CustomerID:\t%-4d\t\tName: %s\n\t\t\t\tAddress: %s\n
3 Customer: %d / %s (%s)\n

## sampledata:
5 Companyname 123 Somewhere Street
12 Othercompany 234 Elsewhere

我的希望是我能够构造这样的东西，通过一次 awk 调用来完成整个事情，而不是在 shell 中使用嵌套循环：

awk '

  NR==FNR { fmts[$1]=$2; next; }

  {
    for(fmtid in fmts) {
      outputfile=sprintf("/path/%d/%d", fmtid, custid);
      printf(fmts[fmtid], $1, $2) > outputfile;
    }
  }

' /path/to/fmtstrings /path/to/sampledata

显然，这是行不通的，既因为这个问题的实际主题，也因为我还没有弄清楚如何优雅地使 awk 将 $2..$n 连接到单个变量中。 （但这是未来可能出现的问题的主题。）

FWIW，我正在使用内置的 FreeBSD 9.2，但如果可以找到解决方案，我愿意使用 gawk。

为什么这个例子如此冗长和复杂？这说明了这个问题：

$ echo "" | awk '{s="a\t%s"; printf s"\n","b"}'
a       b

$ echo "a\t%s" | awk '{s=$0; printf s"\n","b"}'
a\tb

在第一种情况下，字符串“a\t%s”是字符串文字，因此会被解释两次 - 一次是在 awk 读取脚本时，另一次是在执行脚本时，因此\t在第一次传递时展开，然后在执行时 awk 在格式化字符串中有一个文本制表符。

在第二种情况下，awk 在格式化字符串中仍然具有字符反斜杠和 t - 因此行为不同。

您需要一些东西来解释这些转义字符，一种方法是调用 shell 的 printf 并读取结果（根据 @EtanReiser 的出色观察进行更正，我在应该使用单引号的地方使用了双引号，在这里由 \047 实现，以避免 shell 扩展）：

$ echo 'a\t%s' | awk '{"printf \047" $0 "\047 " "b" | getline s; print s}'
a       b

如果你不需要变量中的结果，你可以调用system().

如果您只是想扩展转义字符，那么您不需要提供%sshell 中的参数printf打电话，你只需要逃避所有%s（注意已经逃逸的%s).

你可以调用 awk 而不是 shellprintf如果你更喜欢。

请注意，这种方法虽然笨拙，但比调用eval这可能只是执行一个输入行，例如rm -rf /*.*!

在 Arnold Robbins（gawk 的创建者）和 Manuel Collado（另一位著名的 awk 专家）的帮助下，以下脚本将扩展单字符转义序列：

$ cat tst2.awk
function expandEscapes(old,     segs, segNr, escs, idx, new) {
    split(old,segs,/\\./,escs)
    for (segNr=1; segNr in segs; segNr++) {
        if ( idx = index( "abfnrtv", substr(escs[segNr],2,1) ) )
            escs[segNr] = substr("\a\b\f\n\r\t\v", idx, 1)
        new = new segs[segNr] escs[segNr]
    }
    return new
}

{
    s = expandEscapes($0)
    printf s, "foo", "bar"
}

.

$ awk -f tst2.awk <<<"hello: %s\nworld: %s\n"
hello: foo
world: bar

或者，这应该在功能上等效，但不是特定于 gawk 的：

function expandEscapes(tail,   head, esc, idx) {
    head = ""
    while ( match(tail, /\\./) ) {
        esc  = substr( tail, RSTART + 1, 1 )
        head = head substr( tail, 1, RSTART-1 )
        tail = substr( tail, RSTART + 2 )
        idx  = index( "abfnrtv", esc )
        if ( idx )
             esc = substr( "\a\b\f\n\r\t\v", idx, 1 )
        head = head esc
    }

    return (head tail)
} 

如果您愿意，可以将 split() RE 更改为

/\\(x[0-9a-fA-F]*|[0-7]{1,3}|.)/

以及之后的十六进制值\\:

c = sprintf("%c", strtonum("0x" rest_of_str))

对于八进制值：

c = sprintf("%c", strtonum("0" rest_of_str))