如何在 SBCL/Common Lisp 中与进程输入/输出交互

我有一个文本文件，每行一个句子。我想使用 hunspell （-s 选项）对每行中的世界进行词形还原。由于我想分别获得每行的引理，因此将整个文本文件提交给 hunspell 是没有意义的。我确实需要一行接一行地发送，并为每一行提供 hunspell 输出。

遵循以下答案如何在 Steel Bank Common Lisp 中处理输入和输出流？ https://stackoverflow.com/q/2353353/121095，我能够一行又一行地发送 hunspell 的整个文本文件，但我无法捕获每一行的 hunspell 输出。在发送另一行之前如何与发送行并读取输出的进程进行交互？

我当前读取整个文本文件的代码是

(defun parse-spell-sb (file-in)
  (with-open-file (in file-in)
    (let ((p (sb-ext:run-program "/opt/local/bin/hunspell" (list "-i" "UTF-8" "-s" "-d" "pt_BR") 
                 :input in :output :stream :wait nil)))
      (when p
        (unwind-protect 
          (with-open-stream (o (process-output p)) 
            (loop 
         :for line := (read-line o nil nil) 
         :while line 
         :collect line)) 
          (process-close p))))))

这段代码再次为我提供了整个文本文件的 hunspell 输出。我想分别为每个输入行提供 hunspell 的输出。

任何想法？

我想您要运行的程序存在缓冲问题。例如：

(defun program-stream (program &optional args)
  (let ((process (sb-ext:run-program program args
                                     :input :stream
                                     :output :stream
                                     :wait nil
                                     :search t)))
    (when process
      (make-two-way-stream (sb-ext:process-output process)
                           (sb-ext:process-input process)))))

现在，在我的系统上，这将适用于cat:

CL-USER> (defparameter *stream* (program-stream "cat"))
*STREAM*
CL-USER> (format *stream* "foo bar baz~%")
NIL
CL-USER> (finish-output *stream*)       ; will hang without this
NIL
CL-USER> (read-line *stream*)
"foo bar baz"
NIL
CL-USER> (close *stream*)
T

注意finish-output http://clhs.lisp.se/Body/f_finish.htm– 如果没有这个，读取将会挂起。 （还有force-output http://clhs.lisp.se/Body/f_finish.htm.)

交互模式下的 Python 也可以工作：

CL-USER> (defparameter *stream* (program-stream "python" '("-i")))
*STREAM*
CL-USER> (loop while (read-char-no-hang *stream*)) ; skip startup message
NIL
CL-USER> (format *stream* "1+2~%")
NIL
CL-USER> (finish-output *stream*)
NIL
CL-USER> (read-line *stream*)
"3"
NIL
CL-USER> (close *stream*)
T

但如果你在没有-i选项（或类似的选项，例如-u），你可能会运气不好，因为缓冲正在进行。例如，在我的系统上，读取tr将挂起：

CL-USER> (defparameter *stream* (program-stream "tr" '("a-z" "A-Z")))
*STREAM*
CL-USER> (format *stream* "foo bar baz~%")
NIL
CL-USER> (finish-output *stream*)
NIL
CL-USER> (read-line *stream*)          ; hangs
; Evaluation aborted on NIL.
CL-USER> (read-char-no-hang *stream*)
NIL
CL-USER> (close *stream*)
T

Since tr不提供关闭缓冲的开关，我们将使用 pty 包装器来包装调用（在本例中unbuffer从预期）：

CL-USER> (defparameter *stream* (program-stream "unbuffer"
                                                '("-p" "tr" "a-z" "A-Z")))
*STREAM*
CL-USER> (format *stream* "foo bar baz~%")
NIL
CL-USER> (finish-output *stream*)
NIL
CL-USER> (read-line *stream*)
"FOO BAR BAZ
"
NIL
CL-USER> (close *stream*)
T

所以，长话短说：尝试使用finish-output在阅读之前在流上。如果这不起作用，请检查阻止缓冲的命令行选项。如果仍然不起作用，您可以尝试将程序包装在某种 pty 包装器中。