Gradle 无法解决 Android Studio 中的依赖关系

我在 Android Studio 中导入了一个 Phonegap 项目，并将其设为基于 Gradle 的项目。
现在我正在尝试编译一些外部依赖项，但出现此错误：

错误：(72, 13) 无法解析：com.loopj.android:android-async-http:1.4.6 在文件中显示
在项目结构对话框中显示

我尝试通过进入“文件”->“项目结构”->“依赖项”并“自动”添加它们来添加这些依赖项。 Android Studio 确实找到了这些库，并将它们添加到我的 build.gradle 中，但我仍然遇到相同的错误...

这是我的 build.gradle 文件的一部分（依赖项位于底部）：

import java.util.regex.Pattern

apply plugin: 'android'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:1.1.0+'
    }
}

ext.multiarch=false

android {
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }
    }

    defaultConfig {
        versionCode Integer.parseInt("" + getVersionCodeFromManifest() + "0")
    }

    compileSdkVersion 21
    buildToolsVersion "21.0.0"

    if (multiarch || System.env.BUILD_MULTIPLE_APKS) {
        productFlavors {
            armv7 {
                versionCode defaultConfig.versionCode + 2
                ndk {
                    abiFilters "armeabi-v7a", ""
                }
            }
            x86 {
                versionCode defaultConfig.versionCode + 4
                ndk {
                    abiFilters "x86", ""
                }
            }
            all {
                ndk {
                    abiFilters "all", ""
                }
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
    compile 'com.android.support:appcompat-v7:22.0.0'
    compile 'com.google.android.gms:play-services:6.5.87'
    compile 'com.loopj.android:android-async-http:1.4.6'
    compile 'org.altbeacon:android-beacon-library:2+@aar'
    for (subproject in getProjectList()) {
        compile project(subproject)
    }
}

谢谢你的帮助 ：）

这不应该在里面buildscript，把它放在外面buildscript. use jcenter() or mavenCentral()根据您的要求。

repositories {
    mavenCentral()
}

另外您使用了错误的插件。如果为应用程序构建，请使用

apply plugin: 'com.android.application'

如果为图书馆而建，请使用

apply plugin: 'com.android.library'