如何使用一对 FrameLabels 制作绘图网格？

创建行/列/网格图（整个网格具有单个 FrameLabel）的最简单方法是什么？

我需要类似的东西：

p := ListPlot[RandomInteger[10, 5], Joined -> True, Axes -> False, 
  Frame -> True, PlotRange -> {0, 11}, 
  FrameLabel -> {"horizontal", None}, AspectRatio -> 1]

GraphicsRow[{Show[p, FrameLabel -> {"horizontal", "vertical"}], p, p}]

对于行格式，它可以有一个或多个水平标签，但只能有一个垂直标签。

需要考虑的问题：

• 垂直比例必须与所有地块相匹配，并且不得被例如标签太长或自动PlotRangePadding.
• 需要对图间间距进行良好（并且可调整大小！）的控制（毕竟，这是删除冗余标签的动机之一）
• 布置的总体空间效率。最大内容，最小（不必要的）空白。

EDIT

我试图能够稳健地创建可打印的图形，这涉及大量的大小调整。 （因为导出的PDF通常不会与我在笔记本中看到的比例相同，并且必须具有可读但不是过大的字体）

您可以使用等级方案 http://scidraw.nd.edu/levelscheme/实现你想要的。这是一个例子：

<< "LevelScheme`"
Figure[{
  Multipanel[{{0, 1}, {0, 1}}, {1, 3},
   XFrameLabels -> textit["x"], BufferB -> 3,
   YFrameLabels -> textit["Sinc(x)"], BufferL -> 3,
   TickFontSize -> 9,
   XGapSizes -> {0.1, 0.1},
   PanelLetterCorner -> {1, 1}
   ],
  FigurePanel[{1, 1}, PlotRange -> {{-1.6, -0.6}, {-0.5, 1}}],
  RawGraphics[Plot[Sinc[20 x], {x, -1.6, -0.6}]],

  FigurePanel[{1, 2}, PlotRange -> {{-0.5, 0.5}, {-0.5, 1}}],
  RawGraphics[Plot[Sinc[20 x], {x, -0.5, 0.5}]],

  FigurePanel[{1, 3}, PlotRange -> {{0.6, 1.6}, {-0.5, 1}}],
  RawGraphics[Plot[Sinc[20 x], {x, 0.6, 1.6}]]
  },
 PlotRange -> {{-0.1, 1.02}, {-0.12, 1.095}}]

LevelScheme 为您的情节安排提供了极大的灵活性。

• 您可以将定义移动到绘图中，而不是为绘图提供通用标签FigurePanel[]并单独控制每个标签。
• 您可以在 X 和 Y 方向上设置图间间距，还可以更改每个面板的大小，例如，左边的面板可以占用 2/3 的空间，而接下来的两个面板各占 1/6 的空间。
• 您可以设置单独的绘图范围，更改每个绘图的框架刻度标签，控制应标记面板的哪一侧（顶部/底部/左/右），更改面板编号等。

唯一的缺点是你可能不得不与它搏斗一些案例 https://stackoverflow.com/questions/5465606/histogram-plots-in-levelscheme，但总的来说，我发现它使用起来很愉快。

EDIT

这是与您的示例类似的一个：

Figure[{
  Multipanel[{{0, 1}, {0, 1}}, {1, 3},
   YFrameLabels -> textit["Vertical"], BufferL -> 3,
   TickFontSize -> 9,
   XGapSizes -> {0.1, 0.1},
   PanelLetterCorner -> {1, 1}
   ],
  FigurePanel[{1, 1}, PlotRange -> {{1, 10}, {0, 10}}],
  RawGraphics[ListLinePlot[RandomInteger[10, 10]]],

  FigurePanel[{1, 2}, PlotRange -> {{1, 10}, {0, 10}},
   LabB -> textit["Horizontal"], BufferB -> 3],
  RawGraphics[ListLinePlot[RandomInteger[10, 10]]],

  FigurePanel[{1, 3}, PlotRange -> {{1, 10}, {0, 10}}],
  RawGraphics[ListLinePlot[RandomInteger[10, 10]]]
  },
 PlotRange -> {{-0.1, 1.02}, {-0.2, 1.095}}]

EDIT 2

为了回答向导先生的评论，这里有一个空白模板2x3 grid

Figure[{Multipanel[{{0, 1}, {0, 1}}, {2, 3},
   XFrameTicks -> None,
   YFrameTicks -> None,
   XGapSizes -> {0.1, 0.1},
   YGapSizes -> {0.1}],
  FigurePanel[{1, 1}],
  FigurePanel[{1, 2}],
  FigurePanel[{1, 3}],
  FigurePanel[{2, 1}],
  FigurePanel[{2, 2}],
  FigurePanel[{2, 3}]
  }, PlotRange -> {{-0.01, 1.01}, {-0.01, 1.01}}]    

这是带有扩展面板的一个

Figure[{Multipanel[{{0, 1}, {0, 1}}, {2, 3},
   XFrameTicks -> None,
   YFrameTicks -> None,
   XGapSizes -> {0.1, 0.1},
   YGapSizes -> {0.1}],
  FigurePanel[{1, 1}, PanelAdjustments -> {{0, 0}, {1.1, 0}}],
  FigurePanel[{1, 2}],
  FigurePanel[{1, 3}],
  FigurePanel[{2, 2}, PanelAdjustments -> {{0, 1.1}, {0, 0}}]
  }, PlotRange -> {{-0.01, 1.01}, {-0.01, 1.01}}]