使用 ParamArray（相对于 Variant 数组）有什么好处？

我用过ParamArray当我想接受可变数量的参数时，我声明了多年。 MinVal 函数就是一个很好的例子：

Function MinVal(ParamArray Values() As Variant)
    Dim ReturnVal As Variant, v As Variant

    If UBound(Values) < 0 Then
        ReturnVal = Null
    Else
        ReturnVal = Values(0)
        For Each v In Values
            If v < ReturnVal Then ReturnVal = v
        Next v
    End If
    MinVal = ReturnVal

End Function
' Debug.Print MinVal(10, 23, 4, 17)
' 4

可以在没有 ParamArray 的情况下将其重写为：

Function MinVal(Optional Values As Variant)
    Dim ReturnVal As Variant, v As Variant

    If IsMissing(Values) Or IsNull(Values) Then
        ReturnVal = Null
    Else
        ReturnVal = Values(0)
        For Each v In Values
            If v < ReturnVal Then ReturnVal = v
        Next v
    End If
    MinVal = ReturnVal

End Function
' Debug.Print MinVal(Array(10, 23, 4, 17))
' 4

请注意，在第二个示例中使用Array()调用 MinVal 中的函数。

第二种方法的优点是能够将参数数组传递给另一个也接受数组的函数。如果我希望能够将参数数组传递给MinVal到其他一些功能。

我开始想我应该always赞成这种方法并停止使用ParamArray共。

有人可能会争辩说，使用ParamArray使得代码更明确可读。但是，编译时检查没有任何优势，因为ParamArray must是一个变体数组。谁能提供一个令人信服的理由ever use ParamArray?

我的大部分ParamArray函数有 stdArray像这样完成繁重工作的版本：

Private Sub Command2_Click()
    Process 1, 2, 3
End Sub

Private Sub Process(ParamArray A() As Variant)
    ProcessArray CVar(A)
End Sub

Private Sub ProcessArray(B As Variant)
    Debug.Print UBound(B)
End Sub

但这对于输出参数不起作用，所以是的替换ParamArray with Array变得非常快，对于输出参数来说非常不方便。