为什么来自类的java字节码出现新静态内部类的代码出现jvm指令ACONST_NULL

我尝试新建一个内部静态类，但我发现字节码出现了jvm指令ACONST_NULL bwteen NEW,DUP and INVOKE_SPECIAL, 但我知道一门新课是

• NEW
• DUP
• 调用_特殊

package com.hoho.api;

/**
 * @author linuxea
 */
public class Main {

    private static class InnerMain {
        // no field
    }

    public static void main(String[] args) {
        InnerMain innerMain = new InnerMain();
    }

}

// class version 52.0 (52)
// access flags 0x21
public class com/hoho/api/Main {

  // compiled from: Main.java
  // access flags 0xA
  private static INNERCLASS com/hoho/api/Main$InnerMain com/hoho/api/Main InnerMain
  // access flags 0x1008
  static synthetic INNERCLASS com/hoho/api/Main$1 null null

  // access flags 0x1
  public <init>()V
   L0
    LINENUMBER 6 L0
    ALOAD 0
    INVOKESPECIAL java/lang/Object.<init> ()V
    RETURN
   L1
    LOCALVARIABLE this Lcom/hoho/api/Main; L0 L1 0
    MAXSTACK = 1
    MAXLOCALS = 1

  // access flags 0x9
  public static main([Ljava/lang/String;)V
    // parameter  args
   L0
    LINENUMBER 13 L0
    NEW com/hoho/api/Main$InnerMain
    DUP
    ACONST_NULL
    INVOKESPECIAL com/hoho/api/Main$InnerMain.<init> (Lcom/hoho/api/Main$1;)V
    ASTORE 1
   L1
    LINENUMBER 14 L1
    RETURN
   L2
    LOCALVARIABLE args [Ljava/lang/String; L0 L2 0
    LOCALVARIABLE innerMain Lcom/hoho/api/Main$InnerMain; L1 L2 1
    MAXSTACK = 3
    MAXLOCALS = 2
}

Why

 L0
    LINENUMBER 13 L0
    NEW com/hoho/api/Main$InnerMain
    DUP
    ACONST_NULL
    INVOKESPECIAL com/hoho/api/Main$InnerMain.<init> (Lcom/hoho/api/Main$1;)V
    ASTORE 1

是什么ACONST_NULL?

这就是方法javac解决JDK 11之前的私有成员访问问题。

InnerMain被声明为私有，并且它有私有的默认构造函数：

private InnerMain() {
}

根据JVM规范，任何类都不能访问其他类的私有成员，但是根据Java语言规则，Main应该能够访问私有成员InnerMain。为了解决这个问题，javac生成一个合成包私有桥构造函数。为了确保不会直接从用户代码调用此构造函数，编译器添加了一个虚拟类Main$1在签名中：

// Real constructor
private InnerMain() {
}


// Synthetic bridge constructor (package private, so Main can call it)
InnerMain(Main$1 dummy) {
    this();
}

当你写的时候new InnerMain()，编译器实际上调用了这个桥构造函数。虚拟参数的实际值并不重要，因此只需将其设置为null- 因此ACONST_NULL操作说明：

public static void main(String[] args) {
    InnerMain innerMain = new InnerMain(null);
}

请注意，当内部类是公共或包私有时，不需要桥接方法。

自 JDK 11 以来，引入了一种全新的机制，请参阅JEP 181：基于嵌套的访问控制 https://openjdk.java.net/jeps/181。现在，如果您使用 JDK 11 或更高版本编译 Main 类，Main and InnerMain将成为巢友，并且能够在没有桥接方法和合成类的情况下访问彼此的私有成员。