压缩 (zip) 无法创建输出文件 - 错误

我正在使用 VBscript 扫描文件夹、创建 zip 文件并向其中添加文件（压缩），但是当我在包含大量文件的文件夹上运行脚本时，出现以下错误：“压缩 (zip) 无法创建输出文件”

我的邮政编码处理代码如下：

Dim objFSO
Set objFSO= CreateObject("Scripting.FileSystemObject"

Function PreformZip(objFile,target,zip_name, number_of_file)

  Set shell = CreateObject("WScript.Shell")  
  zip_target = target + "\" + zip_name +".zip" 
  If Not objFSO.FileExists(zip_target) Then
    MakePathIfNotExist(target) 
    NewZip(zip_target)
  Else
    If number_of_file=0 Then
        objFSO.DeleteFile(zip_target)
        NewZip(zip_target)
    End if
  End If

  Set zipApp = CreateObject("Shell.Application")
  aSourceName = Split(objFile, "\")
  sSourceName = (aSourceName(Ubound(aSourceName)))
  zip_file_count = zipApp.NameSpace(zip_target).items.Count
  zipApp.NameSpace(zip_target).Copyhere objFile, 16
  On Error Resume Next
  sLoop = 0
  Do Until zip_file_count < zipApp.NameSpace(zip_target).Items.Count
    Wscript.Sleep(100)
    sLoop = sLoop + 1
  Loop
  On Error GoTo 0
End Function

Sub NewZip(zip)
  Set new_zip = objFSO.CreateTextFile(zip)
  new_zip.Write Chr(80) & Chr(75) & Chr(5) & Chr(6) & String(18, 0)  
  new_zip.Close
  Set new_zip = Nothing 
  WScript.Sleep(5000)
End Sub

Function MakePathIfNotExist(DirPath)
Dim FSO, aDirectories, sCreateDirectory, iDirectory

Set FSO = CreateObject("Scripting.FileSystemObject")
If FSO.FolderExists(DirPath) Then
  Exit Function
End If

aDirectories = Split(DirPath, "\")
sCreateDirectory = aDirectories(0)
For iDirectory = 1 To UBound(aDirectories)
  sCreateDirectory = sCreateDirectory & "\" & aDirectories(iDirectory)
  If Not FSO.FolderExists(sCreateDirectory) Then
  FSO.CreateFolder(sCreateDirectory)
  End If
Next
End Function

Function Recursion(DirectoryPath)
Dim FSO : Set FSO = CreateObject("Scripting.FileSystemObject")

If FSO.FolderExists(DirectoryPath) Then Exit Function
Call Recursion(FSO.GetParentFolderName(DirectoryPath))
FSO.CreateFolder(DirectoryPath)
End Function

我首先以为创建 zip 后等待的时间不够长，但我什至尝试在每个 zip 后等待 10 秒，但仍然遇到相同的错误。

我该如何解决？

如果没有解决方案，是否有其他方法来制作拉链？该脚本不仅供我自己使用，所以我不想在需要安装的软件上进行中继？

虽然Folder.CopyHere方法不返回值，并且不会向调用程序发出任何通知来指示复制已完成，您可以等待下一个代码片段，我希望您可以在脚本中看到正确的（重新）放置：

On Error GoTo 0
zipApp.NameSpace(zip_target).Copyhere objFile _
      , 4 +8 +16 +256 +512 +1024
Wscript.Sleep( 100)
On Error GoTo 0

注意：无需等待Do..Loop, this Wscript.Sleep( 100)足以压缩小文件或在大文件的情况下启动进度对话框 - 并且您的脚本将等待它......

注意：无'On Error Resume Next。避免调用On Error Resume Next如果你不处理错误...

使用的标志如下。

Const FOF_SILENT            = &h0004 'ineffective?
Const FOF_RENAMEONCOLLISION = &h0008 'ineffective?
Const FOF_NOCONFIRMATION    = &h0010 '
Const FOF_SIMPLEPROGRESS    = &h0100 'ineffective?
Const FOF_NOCONFIRMMKDIR    = &h0200 '
Const FOF_NOERRORUI         = &h0400 '

不幸的是，在某些情况下，例如压缩（.zip) 文件，某些选项标志可能会被设计忽略（原文如此！）由 MSDN 提供 http://msdn.microsoft.com/en-us/library/windows/desktop/bb787866(v=vs.85).aspx!

If FOF_SILENT标记无效，然后用户可以Cancel压缩过程...

If FOF_RENAMEONCOLLISION标志无效，则不会压缩较新的同名文件，现有的 zip 文件保留以前的版本，无需注意；只有现有文件夹才会出现额外的错误消息...

这些也可以解决，但这是另一个问题的主题......