IF @@Rowcount = 0 -- Access 中的 SQL 语法错误

我在 Excel 中有一个子例程，我想将数据写入 Access 表。我正在尝试更新表中的行（如果已存在），如果不存在则添加它。即将离开建议 http://blogs.msdn.com/b/miah/archive/2008/02/17/sql-if-exists-update-else-insert.aspxJeremiah Clark 在 MSDN 博客上给出了我的查询，我将从 Excel 的 VBA 子例程中执行：

UPDATE tblName 
SET  [Column1] = 'text', ...(other values)... [ColumnN] = 1234 

WHERE ([Column1] = 'text' AND [Column2] = 'text2')

If @@ROWCOUNT = 0

INSERT INTO  tblName

VALUES   ( [Column1] = 'text', ...(other values)... [ColumnN] = 1234 )

它给我的错误是：

Syntax error (missing operator) in query expression '([Column1] = 'text' AND [Column2] = 'text2')

If @@ROWCOUNT = 0

INSERT INTO  tblName

VALUES   ( [Column1] = 'text', ...(other values)...'.

我对 SQL 还很陌生，但是尝试了各种方法将 IF 行括起来，以防评估顺序不是我所期望的，但这没有用。查询的第一部分是否未被评估，因此 @@ROWCOUNT 无法正确执行？

Edit1：如果重要的话，请使用 Access 2003。

解决方案：基于蓝脚的建议 https://stackoverflow.com/questions/6913258/if-rowcount-0-sql-syntax-error-in-access/6913537#6913537（查看他的完整回复）：

objDB.Execute sqlStrSelect
recordset.Source = sqlStrSelect
recordset.Open , , adOpenDynamic, adLockOptimistic

If recordset.Fields(0) = 0 Then
  objDB.Execute sqlStrInsert
Else
  objDB.Execute sqlStrUpdate
End If

这依赖于修改后的 SELECT 查询来让 Access 返回记录的计数：

sqlStrSelect = "SELECT Count(id) FROM table1 WHERE id = 3"

HansUp 正确地推测我正在使用 ADO 连接，因此执行代码的方式必须与 bluefeet 最初建议的方式不同。

The @@ROWCOUNT用于 SQL Server 而不是 Access，但因为您正在使用VBA你可以做类似的事情。基本上将 SQL 语句创建为字符串，放入要检查的值。然后首先对表运行查询以查看该记录是否存在，如果存在则执行UPDATE如果没有那么做INSERT。我很快在 MS Access 2003 中对此进行了测试，并且它有效。

Public Sub test()
    Dim sqlStrUpdate As String
    Dim sqlStrSelect As String
    Dim sqlStrInsert As String
    Dim recordSet As recordSet

    sqlStrUpdate = "UPDATE table1 SET Field1 = " & 5 & " WHERE id = 3"

    sqlStrSelect = "SELECT id FROM table1 WHERE id = 3"

    sqlStrInsert = "INSERT INTO table1 (id, Field1, Field2, Field3) VALUES (3, 5, 0, 0)"

    Set recordSet = CurrentDb.OpenRecordset(sqlStrSelect)

    If recordSet.RecordCount > 0 Then
        DoCmd.RunSQL (sqlStrUpdate)
    ElseIf recordSet.RecordCount = 0 Then
        DoCmd.RunSQL (sqlStrInsert)
    End If

End Sub

编辑：正如 HansUp 指出您正在从 Excel 进行查询，您的代码可能类似于：

Public Sub test_new()
Dim cDir_Database         As String
Dim DB_Conn               As New ADODB.Connection         'Access Connection
Dim DB_RSet               As New ADODB.recordSet          'Access Record Set

Dim sqlStrUpdate As String
Dim sqlStrInsert As String

cDir_Database = ".\.\.AccessBD.mdb "

sqlStrUpdate = "UPDATE table1 SET Field1 = " & 10 & " WHERE id = 4"

sqlStrInsert = "INSERT INTO table1 (id, Field1, Field2, Field3) VALUES (4, 5, 0, 0)"

        DB_Conn.ConnectionString = "Driver={Microsoft Access Driver (*.mdb)};" & _
                            "DBQ=" & cDir_Database & ";"
        DB_Conn.Open
        DB_Conn.BeginTrans

        DB_RSet.Open "SELECT id FROM table1 WHERE id = 4", DB_Conn, adOpenStatic, adLockReadOnly

        If DB_RSet.RecordCount > 0 Then
            DB_Conn.Execute (sqlStrUpdate)
        ElseIf DB_RSet.RecordCount = 0 Then
            DB_Conn.Execute (sqlStrInsert)
        End If

        DB_RSet.Close
        DB_Conn.CommitTrans
        DB_Conn.Close

End Sub

这已经从 Excel 2003 到 Access 2003 进行了测试并且有效。您需要将 Microsoft ActiveX 数据对象的引用添加到 Excel 文件中。