有没有办法使用 Perl 脚本更改 Windows 文件夹图标？

有没有办法使用 Perl 脚本更改 Windows 文件夹图标？

我的目的是将“xxx_documents”文件夹的普通图标更改为其他图标。我必须以照顾整个驱动器的方式运行脚本。

该驱动器包含许多文件夹。我必须搜索每个名为“文档”的文件夹（例如“xxx_documents”或简单的“文档”）并将其图标更改为"%SystemRoot%\system32\SHELL32.dll"图书馆。

这在 Perl 中可能吗？感谢所有帮助我的人。

你肯定可以用 Perl 做到这一点。 Windows 使用隐藏系统控制目录图标Dekstop.ini每个文件夹中的文件。内容看起来像这样：

 [.ShellClassInfo]
 IconFile=%SystemRoot%\system32\SHELL32.dll
 IconIndex=41

在 Windows XP 上（我假设在其他系统上），图标 41 是一棵树。 Windows 要求将此文件显式设置为system文件才能正常工作，这意味着我们需要深入研究Win32API::File创建它：

 #!/usr/bin/perl
 use strict;
 use warnings;

 use Win32API::File qw(createFile WriteFile fileLastError CloseHandle);

 my $file = createFile(
      'Desktop.ini',
      {
           Access     => 'w',        # Write access
           Attributes => 'hs',       # Hidden system file
           Create     => 'tc',       # Truncate/create
      }
 ) or die "Can't create Desktop.ini - " . fileLastError();

 WriteFile(
      $file,
      "[.ShellClassInfo]\r\n" .
      "IconFile=%SystemRoot%\\system32\\SHELL32.dll\r\n" .
      "IconIndex=41\r\n",
      0, [], []
 ) or die "Can't write Desktop.ini - " . fileLastError();

 CloseHandle($file) or die "Can't close Desktop.ini - " . fileLastError();

如果运行上面的代码，它应该将当前目录的图标设置为树。在资源管理器接受更改之前，您可能需要刷新目录列表。

现在我们有了更改图标的方法，现在我们可以遍历整个驱动器并更改与我们的模式匹配的每个文件夹。我们可以很容易地做到这一点File::Find，或其替代方案之一（例如，File::Find::Rule, or File::Next):

 #!/usr/bin/perl
 use strict;
 use warnings;
 use File::Find qw(find);
 use Win32API::File qw(createFile WriteFile fileLastError CloseHandle);

 my $topdir = $ARGV[0] or die "Usage: $0 path\n";

 find( \&changeIcon, $topdir);

 sub changeIcon {
     return if not /documents$/i;   # Skip non-documents folders
     return if not -d;              # Skip non-directories.

     my $file = createFile(
         "$_\\Desktop.ini",
         {
              Access     => 'w',        # Write access
              Attributes => 'hs',       # Hidden system file
              Create     => 'tc',       # Truncate/create
         }
     ) or die "Can't create Desktop.ini - " . fileLastError();

     WriteFile(
         $file,
         "[.ShellClassInfo]\r\n" .
         "IconFile=%SystemRoot%\\system32\\SHELL32.dll\r\n" .
         "IconIndex=41\r\n",
         0, [], []
     ) or die "Can't write Desktop.ini - " . fileLastError();

     CloseHandle($file) or die "Can't close Desktop.ini - " . fileLastError();
 }

不幸的是，我刚刚发现该图标only如果目录当前有或曾经有图标，则会发生更改...显然，在目录本身上设置了一个属性，该属性会导致 Windows 查找Desktop.ini文件，但我一生都无法弄清楚它是什么。因此，上述解决方案是不完整的；我们还需要找到并修复要添加图标的目录的属性。

Paul