我从文本文件中分割一个字符串并将其放入一个数组中，但是每当我输出该数组时，它们都会用 0 填充

我的代码基本上将 3 个随机变量输入到一个文本文件中，并用“:”分隔每个变量。我的代码的第二部分基本上再次读取文本文件，并使用我之前输入的 MID 函数对字符串进行切片以获取第二个变量，并将其添加到数组中。但是当我输出数组时，它全是 0。我试图找出问题所在，但我不知道。

这是我的代码：

Dim r1, r2, r3, counter, counter1, counter2, sep As Integer
Dim line As String
Dim middleline(20)
line = ""
counter1 = 0
sep = 0
FileSystem.FileOpen(1, "C:\Users\user\OneDrive\Desktop\binarysearch.txt", OpenMode.Output, OpenAccess.Write)
For counter = 1 To 20
    If Rnd() = 0.21 Then
        r1 = -1
    Else
        Do
            r1 = Rnd() * 100
        Loop Until r1 <= 20
    End If
    Do
        r2 = Rnd() * 100
    Loop Until r2 >= 10 AndAlso r2 <= 50
    If Rnd() = 0.21 Then
        r3 = -1
    Else
        Do
            r3 = Rnd() * 100
        Loop Until r3 <= 20
    End If
    line = r1 & ":" & r2 & ":" & r3
    FileSystem.WriteLine(1, line)
Next
Console.WriteLine("Generated successfully.")

For counter = 1 To 20
    middleline(counter) = 0
Next

For counter = 1 To 20
    FileSystem.PrintLine(1, line)
    For counter1 = 1 To Len(line)
        If Mid(line, 1, counter1) = ":" Then
            sep += 1
        End If
        If sep = 1 Then
            middleline(counter2) = middleline(counter2) & Mid(line, 1, counter1)
            counter2 += counter2
        End If
    Next
Next

For counter = 1 To 20
    Console.WriteLine(middleline(counter))
Next
Console.WriteLine(middleline)

我不是 100% 确定你的代码哪里出了问题，但我对其进行了一些重写，这似乎工作正常。
我改变了随机数生成，因为我觉得你的循环有点繁重。
还将文件处理切换为更新的方法。

    Private Shared RndGenMachine As Random = New Random

    Public Sub DoWork(FileName As String)

        Dim r1, r2, r3 As Integer
        Dim middleline As List(Of String) = New List(Of String)

        'build the initial file
        Using sw As New StreamWriter(FileName, True)

            For counter As Integer = 1 To 20

                r1 = RndGenMachine.Next(0, 20)
                r3 = RndGenMachine.Next(0, 20)
                r2 = RndGenMachine.Next(10, 50)

                Dim line As String = $"{r1}:{r2}:{r3}"
                sw.WriteLine(line)

            Next

        End Using

        Console.WriteLine("Generated successfully.")

        'read it back for parsing
        Dim lines As IEnumerable(Of String) = File.ReadLines(FileName)

        For lineCounter = 0 To lines.Count - 1

            Dim splits() As String = lines(lineCounter).Split(Convert.ToChar(":"))
            middleline.Add(splits(1))

        Next

        For Each middlelinevalue As String In middleline
            Console.WriteLine(middlelinevalue)
        Next

    End Sub

如果您更喜欢使用旧式文件处理程序，您可以尝试如下操作：

    Public Sub DoWorkOldStyle(FileName As String, iterations As Integer)

        Console.WriteLine("Starting generation...")

        Dim r1, r2, r3 As Integer

        'build the initial file
        FileSystem.FileOpen(1, FileName, OpenMode.Output, OpenAccess.Write)

        For counter As Integer = 1 To iterations

            r1 = RndGenMachine.Next(0, 20)
            r3 = RndGenMachine.Next(0, 20)
            r2 = RndGenMachine.Next(10, 50)

            Dim line As String = $"{r1}:{r2}:{r3}"
            FileSystem.WriteLine(1, line)

        Next

        FileSystem.FileClose(1)

        Console.WriteLine("Generated successfully. Starting evaluation...")

        'read it back for parsing
        FileSystem.FileOpen(1, FileName, OpenMode.Input, OpenAccess.Read)

        Dim middleline As List(Of String) = New List(Of String)

        While Not EOF(1)

            Dim line As String = LineInput(1)
            Dim splits() As String = line.Split(Convert.ToChar(":"))
            middleline.Add(splits(1))

        End While

        FileClose(1)

        For Each middlelinevalue As String In middleline
            Console.WriteLine(middlelinevalue)
        Next

        Console.WriteLine("Evalutaion complete.")

    End Sub