如何在 awk 中复制多维数组（即数组的数组）？

这个问题的目的是用一个非显而易见的解决方案发布一个规范的答案 - 复制数组的数组（需要 GNU awk 用于数组的数组）。

给定一个数组，如 gawk 手册中有关部分所示遍历数组:

BEGIN {
    a[1] = 1
    a[2][1] = 21
    a[2][2] = 22
    a[3] = 3
    a[4][1][1] = 411
    a[4][2] = 42

    walk_array(a, "a")
}

function walk_array(arr, name,      i)
{
    for (i in arr) {
        if (isarray(arr[i]))
            walk_array(arr[i], (name "[" i "]"))
        else
            printf("%s[%s] = %s\n", name, i, arr[i])
    }
}

你会怎么写copy_array可以处理数组数组的函数，将现有数组复制到新数组，以便后续调用walk_array()对于新复制的数组，新数组将输出与原始数组相同的值，即：

BEGIN {
    a[1] = 1
    a[2][1] = 21
    a[2][2] = 22
    a[3] = 3
    a[4][1][1] = 411
    a[4][2] = 42

    walk_array(a, "a")

    copy_array(a, b)

    print "----------"

    walk_array(b, "b")
}

会输出：

a[1] = 1
a[2][1] = 21
a[2][2] = 22
a[3] = 3
a[4][1][1] = 411
a[4][2] = 42
----------
b[1] = 1
b[2][1] = 21
b[2][2] = 22
b[3] = 3
b[4][1][1] = 411
b[4][2] = 42

$ cat tst.awk
BEGIN {
    a[1] = 1
    a[2][1] = 21
    a[2][2] = 22
    a[3] = 3
    a[4][1][1] = 411
    a[4][2] = 42

    walk_array(a, "a")

    copy_array(a, b)

    print "----------"

    walk_array(b, "b")
}

function copy_array(orig, copy,      i)
{
    delete copy         # Empty "copy" for first call and delete the temp
                        # array added by copy[i][1] below for subsequent.
    for (i in orig) {
        if (isarray(orig[i])) {
            copy[i][1]  # Force copy[i] to also be an array by creating a temp
            copy_array(orig[i], copy[i])
        }
        else {
            copy[i] = orig[i]
        }
    }
}

function walk_array(arr, name,      i)
{
    for (i in arr) {
        if (isarray(arr[i]))
            walk_array(arr[i], (name "[" i "]"))
        else
            printf("%s[%s] = %s\n", name, i, arr[i])
    }
}

.

$ awk -f  tst.awk
a[1] = 1
a[2][1] = 21
a[2][2] = 22
a[3] = 3
a[4][1][1] = 411
a[4][2] = 42
----------
b[1] = 1
b[2][1] = 21
b[2][2] = 22
b[3] = 3
b[4][1][1] = 411
b[4][2] = 42

指某东西的用途copy[i][1]在内部调用之前创建一个临时数组copy_array()然后在进入时被删除copy_array()是为了避免后续代码假设存在于copy[i]是一个标量 - 这与在使用之前创建临时数组的方式相同split()（它在内部首先删除作为参数传递的 arry）来填充子数组，因为默认情况下假定数组元素的内容是标量，以便向后兼容为不支持数组数组的 awks 编写的代码（例如 POSIX awks）：

$ printf 'a b\nc d\n' |
  awk '{split($0,arr[NR])} END{for (i in arr) for (j in arr[i]) print i,j,arr[i][j]}'
awk: cmd. line:1: (FILENAME=- FNR=1) fatal: split: second argument is not an array

$ printf 'a b\nc d\n' |
  awk '{arr[NR][1]; split($0,arr[NR])} END{for (i in arr) for (j in arr[i]) print i,j,arr[i][j]}'
1 1 a
1 2 b
2 1 c
2 2 d