如何在 gnuplot 中对箱线图异常值进行分组

我有大量数据点。我尝试用箱线图绘制它们，但一些异常值是完全相同的值，并且它们表示在彼此旁边的一条线上。我发现如何设置gnuplot箱线图中异常值之间的水平距离，但这并没有太大帮助，因为这显然是不可能的。

是否可以将异常值分组在一起，打印一个点，然后在其旁边的括号中打印一个数字以指示有多少个点？我认为这会使图表更具可读性。

作为参考，我在一张图中绘制了 1 个 x 值和 6 个 x 值的三个箱线图。我正在使用 gnuplot 5 并且已经使用了点大小，这不再减少距离。 我希望你能帮忙！

Edit:

set terminal pdf
set output 'dat.pdf'
file0 = 'dat1.dat'
file1 = 'dat2.dat'
file2 = 'dat3.dat'
set pointsize 0.2
set notitle
set xlabel 'X'
set ylabel 'Y'
header = system('head -1 '.file0);
N = words(header)

set xtics ('' 1)
set for [i=1:N] xtics add (word(header, i) i)

set style data boxplot
plot file0 using (1-0.25):1:(0.2) with boxplot lw 2 lc rgb '#8B0000' fs pattern 16 title 'A'
plot file1 using (1):1:(0.2) with boxplot lw 2 lc rgb '#00008B' fs pattern 4 title 'B'
plot file2 using (1+0.25):1:(0.2) with boxplot lw 2 lc rgb '#006400' fs pattern 5 title 'C'
for [i=2:N] plot file0 using (i-0.25):i:(0.2) with boxplot lw 2 lc rgb '#8B0000' fs pattern 16 notitle
for [i=2:N] plot file1 using (i):i:(0.2) with boxplot lw 2 lc rgb '#00008B' fs pattern 4 notitle
for [i=2:N] plot file2 using (i+0.25):i:(0.2) with boxplot lw 2 lc rgb '#006400' fs pattern 5 notitle

使用此代码实现它的最佳方法是什么？

没有选项可以自动完成此操作。在 gnuplot 中手动执行此操作所需的步骤是：

（在下面我假设数据文件data.dat只有一列。）

1. 分析您的数据stats确定异常值的边界：

   stats 'data.dat' using 1
   range = 1.5 # (this is the default value of the `set style boxplot range` value)
   lower_limit = STATS_lo_quartile - range*(STATS_up_quartile - STATS_lo_quartile)
   upper_limit = STATS_up_quartile + range*(STATS_up_quartile - STATS_lo_quartile)
   

2. 仅计算异常值并将其写入临时文件

   set table 'tmp.dat'
   plot 'data.dat' using 1:($1 > upper_limit || $1 < lower_limit ? 1 : 0) smooth frequency
   unset table
   

3. 绘制没有异常值的箱线图，以及有异常值的箱线图labels绘图风格：

   set style boxplot nooutliers
   plot 'data.dat' using (1):1 with boxplot,\
        'tmp.dat' using (1):($2 > 0 ? $1 : 1/0):(sprintf('(%d)', int($2))) with labels offset 1,0 left point pt 7
   

这需要对每个箱线图完成。

免责声明：这个过程应该基本上可以工作，但是没有示例数据，我无法测试它。