number_in_month 练习（SML 列表迭代）

我需要获取日期列表和月份列表，并获取列出的任何月份中的日期数量总数。从而返回一个整数

我有一个先前定义的number_in_month函数，它接受一个列表 日期和一个月，并返回该日期中的日期数量 月。它已经过测试并且工作正常。我以此为基础 后一个功能。我已经追踪过number_in_months功能很多 次，我似乎无法找出问题所在，但它根本没有产生正确的答案

fun number_in_month (datelist : (int*int*int)list, month : int)  = 

let
fun count(x : int , datelist : (int*int*int)list)=
if null (tl datelist)
then x
else if #2(hd datelist) = month
then count(x+1, tl datelist)
else count(x, tl datelist)

in

if #2(hd datelist) = month
then count(1, datelist)
else count(0, datelist)

end

fun number_in_months (datelist : (int*int*int)list, monthlist : (int)list)=
let 
fun count(x : int, monthlist : (int)list)=
if null (tl monthlist)
then x
else count((x + number_in_month(datelist, hd monthlist)), tl monthlist) 

in
count (( number_in_month(datelist, hd monthlist), tl monthlist))
end

正如你所说，你只需要使用前面的功能number_in_month。记住这一点number_in_month接受日期列表和一个月，并返回日期列表中匹配的月份数。因此，创造所需的一切number_in_months, 是调用number_in_month对于新月份列表中的每个元素，并检查原始日期列表。

这样的解决方案可能看起来像

fun number_in_months (dates, months) =
    if null months then
      0
    else
      number_in_month(dates, hd months) + number_in_months(dates, tl months)

但是，当您使用模式匹配时，您可以缩短它并使其更具可读性

fun number_in_months (dates, []) = 0
  | number_in_months (dates, d::ds) =
      number_in_month(dates, d) + number_in_months(dates, ds)

绝对没有理由创建一个count功能，携带“状态”。这似乎是你的命令性思维，在发挥作用:) 以这个简单的函数为例，它将对列表的所有元素求和

fun sum [] = 0
  | sum (x::xs) = x + sum xs

甚至创建一个长度函数（实际上类似于您的计数函数）

fun length [] = 0
  | length (x::xs) = 1 + length xs

我鼓励您阅读这些内容，而不是重复已经多次提到的很多好东西问题以及他们的答案。

Update

我还想向您展示如何以更好的方式格式化代码

fun number_in_month (datelist : (int*int*int) list, month : int)  =
    let
      fun count (x : int , datelist : (int*int*int) list) =
          if null (tl datelist)
          then x
          else if #2(hd datelist) = month
            then count (x+1, tl datelist)
            else count (x, tl datelist)
    in
      if #2(hd datelist) = month
      then count (1, datelist)
      else count (0, datelist)
    end


fun number_in_months (datelist : (int*int*int) list, monthlist : int list)=
    let
      fun count (x : int, monthlist : int list)=
          if null (tl monthlist)
          then x
          else count (x + number_in_month(datelist, hd monthlist), tl monthlist)
    in
      count (number_in_month (datelist, hd monthlist), tl monthlist)
    end

在我所在的地方，如何格式化嵌套的 if 始终是一个激烈的争论。就我个人而言，我避免使用它们，而是使用案例，但我想您将来会倾向于这一点。

不过我还发现你的计数函数有一个错误。当您测试第二个参数（在两个计数函数中）是否为空列表时null，您在参数的尾部执行此操作，如果参数实际上是空列表，则会失败

- null (tl []);

uncaught exception Empty

例如这个输入

- number_in_months ([(1,1,1)], [1]);

uncaught exception Empty

还有你的逻辑number_in_month是错误的，因为您正在测试头部datelist等于month，但是你的count在任何一种情况下都使用整个datelist而不是它的尾巴。这被视为以下结果不应返回 2

- number_in_month([(1,1,1), (2,2,2), (3,3,3)], 1);
val it = 2 : int

这个错误是唯一导致number_in_month函数不抛出异常。