如何在 gnuplot 中创建 3d 相空间图？

看这篇文章封闭但未加密.

我有一些二进制数据。我想执行该文章中所示的 gnuplot，但使用我的数据。

对于三维相空间图，序列 a、b、c、d、e， f等可以作为空间坐标(a-b,b-c,c-d),(b-c,c-d, d-e)、(c-d、d-e、e-f) 等。创建的图中的模式揭示了 后续序列之间的重复关系。在此相图中， 50,000 个 16 位随机数将产生一个非结构化的云 点。

我想做完全相同的事情。我有一个二进制文件（大约 10 MB），我想通过 gnuplot 运行它来创建漂亮的 gnuplot 图表。

我应该在 gnuplot 中输入什么来实现这一点？

在 Google 上搜索“相空间图”和 gnuplot 不会返回太多结果。不知道是不是因为这篇文章是德文翻译的。我认为我没有在堆栈交换站点中找到相关答案。

要绘制 3d 相空间，请使用以下脚本，其工作原理类似于运行平均值示例从 gnuplot 页面：

reset
back4 = back3 = back2 = back1 = 0
shift(x) = (back4 = back3, back3 = back2, back2 = back1, back1 = x)
samples(x) = $0 < 3 ? NaN : x
set ticslevel 0
# the labels are only for orientation when checking the test data
set xlabel 'xlabel'
set ylabel 'ylabel'
splot 'randomdata.dat' using (shift($1), samples(back4-back3)):(samples(back3-back2)):(samples(back2-back1))

Gnuplot 必须保存四个数据值，它们存储在back1 to back4。对于每个新值，存储的值都会移动shift. samples注意不使用前三个值，而仅存储（NaN创建无效数据点）。

要测试它，请使用此文件randomdata.dat:

21
15
10
6
3
1
0

这将在 (6,5,4)、(5,4,3)、(4,3,2) 和 (3,2,1) 处绘制四个数据点。

如果您有一个二进制数据文件，例如16位数字，使用

splot 'binaryfile' binary format="%ushort" using (shift($1), samples(back4-back3)):(samples(back3-back2)):(samples(back2-back1))

如果需要更改数据大小，请调用gnuplot并输入show datafile binary datasizes查看支持哪些格式。